* Encoding: UTF-8.

*********************************************************************************
* SPSS-Programmcode für Zusatzvariablen zur Lebensform und Familiensituation der Befragten
*** 

***
* dh12		LEBENSFORM BEFRAGTE - KURZ

* dh13 		LEBENSFORM BEFRAGTE - FAMILIE

* dh14 		LEBENSFORM NACH MIKROZENSUS-TYPOLOGIE

* dh15		MEHRGENERATIONEN-HAUSHALT

* dh16 		EIG. KINDER IM HAUSHALT: LEDIG, N.LEDIG

* dh17 		ALTER JUENGSTES HAUSHALTSMITGLIED


* Weitere Informationen siehe:

* Sonja Schulz und Sarah Thiesen 2022: Bildung von Zusatzvariablen zur Lebensform und 
* Familiensituation der befragten Person im ALLBUS, GESIS-Papers 2022|12, 
* Köln: GESIS - Leibniz-Institut für Sozialwissenschaften.

* (c) GESIS 2022
* GESIS - Leibniz-Institut für Sozialwisschenschaften
* https://www.gesis.org/allbus
***.

*========================================================================================================*
*========================================================================================================*
*
 !!!!!    BITTE BEACHTEN !!!!!

*  Passen Sie in den Zeilen 545 - 548 bitte Dateinamen und Speicherort der Zieldatei an.
*  In den Zeilen 46 -  114 sind Anpassungen nötig, je nachdem, welchen ALLBUS-Datensatz Sie verwenden.
*  Bitte folgen Sie den Instruktionen.

*========================================================================================================*.
*========================================================================================================*
*====================================================*
* Bitte Pfad und Dateiname des verwendeten ALLBUS-Datensatzes  anpassen:
*====================================================*.

CD '<DATA LOCATION>'.

*GET FILE='ZAxxxx_vx-x-x.sav'.
DATASET NAME ALLBUS WINDOW=FRONT.
MISSING VALUES ALL ().

*====================================================*
* Falls Sie mit dem ALLBUS-Querschnitt 2012 arbeiten, bitte entkommentieren:.
*====================================================*.

*  RENAME VARIABLES (v2 v6 v8 v217 v218 v219 v220 v274 v300 v301 v348 
    v350 v351 v352 v353 v357 v359 v363 v367 v369 v373 v377 v379 v383 v387 
    v389 v393 v397 v399 v403 v407 v409 v413 v417 v419 v429 v430 v740 v741 
    v742 v743 v744 v745 v746 = 
    respid german eastwest sex mborn yborn age mstat dp01 dp03 dh01 
    dh03 dh04 dh09 hh2kin hh2age hh2mstat hh3kin hh3age hh3mstat hh4kin
    hh4age hh4mstat hh5kin hh5age hh5mstat hh6kin hh6age hh6mstat hh7kin
    hh7age hh7mstat hh8kin hh8age hh8mstat dk05 dk06 dh05 dh07 dh08 
    wghtpew wghtht wghthew wghthtew).

 * RECODE dh01 dk05 (9 = -9).
 * RECODE mborn mstat dh04 dh07 (99 = -9).
 * RECODE yborn (9999 = -9).
 * RECODE dp01 dp03 hh2mstat hh3mstat hh4mstat hh5mstat hh6mstat hh7mstat hh8mstat (0 = -10) (9 = -9).
 * RECODE hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin dk06 (0 = -10) (99 = -9).
 * RECODE age (999 = -32).
 * RECODE hh2age hh3age hh4age hh5age hh6age hh7age hh8age (996 = -10) (999 = -32).
 * RECODE dh05 (0 = -10) (999 = -32).
 * RECODE dh08 dh09 (0 = -10) (99 = -32).
 * RECODE wghtpew wghtht wghthew wghthtew (10 = 0).



*====================================================*
* Falls Sie mit dem ALLBUS-Querschnitt 2014 arbeiten, bitte entkommentieren:.
*====================================================*.

 * RENAME VARIABLES (V2 V6 V7 V81 V82 V83 V84 V297 V333 V334 V421 V423 V424 
    V425 V426 V430 V432 V435 V439 V441 V444 V448 V450 V453 V457 
    V459 V462 V466 V468 V471 V475 V477 V480 V484 V486 V527 V528 
    V589 V590 V591 V592 V863 V864 V865 V870 V871 V872 V873 = 
    respid german eastwest sex mborn yborn age mstat dp01 dp03 dh01 
    dh03 dh04 dh09 hh2kin hh2age hh2mstat hh3kin hh3age hh3mstat 
    hh4kin hh4age hh4mstat hh5kin hh5age hh5mstat hh6kin hh6age 
    hh6mstat hh7kin hh7age hh7mstat hh8kin hh8age hh8mstat dk05 dk06 
    dk08a k09a dk08 dk09 dh05 dh07 dh08 wghtpew wghtht wghthew wghthtew).
	
 * RECODE dh01 dk05 (9 = -9).
 * RECODE mborn mstat dh04 (99 = -9).
 * RECODE yborn (9999 = -9).
 * RECODE dp01 dp03 hh2mstat hh3mstat hh4mstat hh5mstat hh6mstat hh7mstat hh8mstat (0 = -10) (9 = -9).
 * RECODE dh03 hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin dk06 dh08 (0 = -10) (99 = -9).
 * RECODE dh07 dh09 (99 = -32).
 * RECODE age (999 = -32).
 * RECODE hh2age hh3age hh4age hh5age hh6age hh7age hh8age (996 = -10) (999 = -32).
 * RECODE dh05 (0, 999 = -32).
 * RECODE wghtpew wghtht wghthew wghthtew (10 = 0).



*====================================================*
* Falls Sie mit den ALLBUS-Querschnitten 2012, 2014, 2016 oder 2018 arbeiten, bitte korrekte Syntax aktivieren.
*====================================================*.

* compute year = 2012.
* compute year = 2014.
* compute year = 2016.
* compute year = 2018.

*====================================================*
* Erstellung __dh12__ 	LEBENSFORM BEFRAGTE KURZ  
*====================================================*.

*-----
* Zunächst Erstellung von Hilfsvariablen zu fehlenden Werten in Angaben der Haushaltsliste, zu Partner, 
* und zu Ehepartner im Haushalt.
*-----.
count hhmiss = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin dh01 dh04 (-99, -42, -41, -32, -9, -8, -7).

*Ehepartner im Haushalt.
compute ehepartner = any(1, hh2kin, hh3kin, hh4kin, hh5kin, hh6kin, hh7kin, hh8kin).

*Lebenspartner im Haushalt.
compute partner = any(2, hh2kin, hh3kin, hh4kin, hh5kin, hh6kin, hh7kin, hh8kin).

* Bei eingetragenen Lebenspartnerschaften (lt. mstat) wird der Partner im Haushalt als Ehepartner gewertet.
if (partner eq 1 AND mstat eq 6) ehepartner = 1.
if (partner eq 1 AND ehepartner eq 1 AND mstat eq 6)  partner = 0.

* bei fehlenden Werten kann man nicht sicher ausschließen, dass ein Partner im Haushalt lebt. Daher Kodierung auf fehlenden Wert.
if ehepartner eq 0 and hhmiss gt 0 ehepartner = -32.
if partner eq 0 and hhmiss gt 0 partner = -32.

compute partner8082 = any(17, hh2kin, hh3kin, hh4kin, hh5kin, hh6kin, hh7kin, hh8kin).
*bei fehlenden Werten kann man nicht sicher ausschließen, dass ein Partner im Haushalt lebt. Daher Kodierung auf fehlenden Wert.
if partner8082 eq 0 and hhmiss gt 0 partner8082 = -32.
if year gt 1982 partner8082 = -1.

*-----
* Erstellung von dh12 LEBENSFORM BEFRAGTE - KURZ
*-----.

compute dh12 = 0.
VALUE LABELS dh12	
    11 "LF1 EHEPAAR"
    21 "LF2 NEL,B:LED."
    22 "LF2 NEL,B:NACHEHE"
    31 "LF3 K.PART(<86)B:LED"
    32 "LF3 K.PART(<86)B:N.EHE"
    33 "LF3 K.PART,B:VERH."
    41 "LF4 LAT,B:LED."
    42 "LF4 LAT,B:NACHEHE"
    51 "LF5 K.PART,B:LED."
    52 "LF5 K.PART,B:NACHEHE"
   -32 "NICHT GENERIERBAR".	
	
VARIABLE LABELS dh12 "LEBENSFORM BEFRAGTE - KURZ".

if any(dh01, -32, -9) OR any(dh04, -32, -9) OR any(dp01, -41, -9, -8, -7) OR mstat lt 0 dh12 = -32.

*-----
*Ab 1986 kann dh12 für alle ALLBUS-Erhebungen ohne Einschränkungen generiert werden.
*-----.

do if year ge 1984.
if ehepartner eq 1						     dh12 = 11.
if partner eq 1 and mstat eq 5					dh12 = 21.
if partner eq 1 and any(mstat, 2, 3, 4, 7, 8, 9)			dh12 = 22.
if ehepartner eq 0 and partner eq 0 and mstat = 1                                                dh12 = 33.
if ehepartner eq 0 and partner eq 0 and mstat = 6                                                dh12 = 33.
if mstat eq 5 and partner eq 0 and ehepartner eq 0 and dp01 eq 1	dh12 = 41.
if any(mstat,  2, 3, 4,  7, 8, 9) and partner eq 0 and ehepartner eq 0 and dp01 eq 1	dh12 = 42.
if mstat eq 5 and partner eq 0 and ehepartner eq 0 and dp01 eq 2			dh12 = 51.
if any(mstat, 2, 3, 4,  7, 8, 9) and partner eq 0 and ehepartner eq 0 and dp01 eq 2	dh12 = 52.
end if.

*-----
*1980-1982 wurden noch keine haushaltsübergreifenden ("living-apart-together", LAT) Paarbeziehungen erhoben. 
*Daher wird für diese Erhebungjahre nur abgebildet, ob eine Paarbeziehung im Haushalt besteht (Codes 11, 21, 22) oder ob keine Paarbeziehung im Haushalt besteht (Alleinlebend, Codes 31, 32).

*Außerdem wurden Ehegatten und nicht-verheiratete Partner in einer gemeinsamen Antwortkategorie der Frage zu Verwandtschaftsbeziehungen im Haushalt erhoben (hh?kin = 17).
*Ehepartner und nicht-eheliche Paare werden daher über den Familienstand der Befragten unterschieden.
*-----.

do if any(year, 1980, 1982).
if partner8082 eq 1 and mstat eq 1					dh12 = 11.
if partner8082 eq 1 and mstat eq 5					dh12 = 21.
if partner8082 eq 1 and any(mstat, 2, 3, 4)			dh12 = 22.
if mstat eq 5 and partner8082 eq 0					dh12 = 31.
if any(mstat, 2, 3, 4) and partner8082 eq 0		dh12 = 32.
if partner8082 eq 0 and mstat eq 1			dh12 = 33.
end if.

*-----
*1984 wurden noch keine haushaltsübergreifenden ("living-apart-together", LAT) Paarbeziehungen erhoben. 
*Daher wird für die Jahre 1980-1984  nur abgebildet, ob eine Paarbeziehung im Haushalt besteht oder ob keine Paarbeziehung im Haushalt besteht (Alleinlebend).

*Personen ohne Partner im Haushalt werden für die Erhebungsjahre 1980, 1982, 1984 auf die Codes 31 und 32 kodiert.
*-----.

do if year eq 1984.
if ehepartner eq 1					dh12 = 11.
if partner eq 1 and mstat eq 5				dh12 = 21.
if partner eq 1 and any(mstat, 2, 3, 4)			dh12 = 22.
if mstat eq 5 and partner eq 0 and ehepartner eq 0		dh12 = 31.
if any(mstat, 2, 3, 4) and partner eq 0 and ehepartner eq 0	dh12 = 32.
if ehepartner eq 0 and partner eq 0 and mstat = 1                       dh12 = 33.
end if.

*-----
*Die übrigen Fälle ohne gültigen Wert auf der Zielvariablen haben auf einer oder auf mehreren Ursprungsvariablen fehlende Werte.
*-----.
if dh12 eq 0     dh12 = -32.												

*====================================================*
* Erstellung __dh16__ 	EIG. KINDER IM HAUSHALT: LEDIG, N.LEDIG *
*====================================================*.

*-----
Erstellung einer Hilfsvariable, die angibt, ob es sich bei einer Haushaltsperson um ein (leibliches, Stief-, Adoptiv-, oder Pflege-) Kind der befragten Person handelt.
*-----.

do repeat #kid = hh2kid hh3kid hh4kid hh5kid hh6kid hh7kid hh8kid / 
                #kin = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin.
compute #kid = $SYSMIS.
if any(#kin, 1, 18) #kid = 0.
if any(#kin, 3, 4) #kid = 1.
end repeat.

*-----
Erstellung einer Hilfsvariable, die den Familienstand des Kindes angibt
*-----.

do repeat #kid = hh2kid hh3kid hh4kid hh5kid hh6kid hh7kid hh8kid / 
                #kin = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin /
                #mstat = hh2mstat hh3mstat hh4mstat hh5mstat hh6mstat hh7mstat hh8mstat /
                #kid_mstat = hh2kid_mstat hh3kid_mstat hh4kid_mstat hh5kid_mstat hh6kid_mstat hh7kid_mstat hh8kid_mstat /
                #age = hh2age hh3age hh4age hh5age hh6age hh7age hh8age.
if (#kid eq 1) #kid_mstat = #mstat.
if any(#mstat, -9, -7, -33) and (#kid eq 1) and range(#age, 0, 15) #kid_mstat = 5.
end repeat.

*-----
Erstellung einer Hilfsvariable, die die Anzahl von Kindern der befragten Person im Haushalt angibt.
*-----.

count anzkid = hh2kid hh3kid hh4kid hh5kid hh6kid hh7kid hh8kid (1).
if (anzkid eq 0 and hhmiss gt 0) anzkid = -32.

*-----
Erstellung von dh16	EIG. KINDER IM HAUSHALT: LEDIG, N.LEDIG
*-----.

compute dh16 = -999.
value labels dh16	
     -32 "NICHT GENERIERBAR" 
    0   "KEINE KINDER IM HH" 
    1   "NUR LED. KINDER" 
    2   "LED. & N.LED. KINDER" 
    3   "NUR N.LED. KINDER".
variable labels dh16 "EIG. KINDER IM HAUSHALT: LEDIG, N.LEDIG".

if (anzkid eq 0) dh16 = 0.

count tmp_nledk = hh2kid_mstat hh3kid_mstat hh4kid_mstat hh5kid_mstat hh6kid_mstat hh7kid_mstat hh8kid_mstat (1, 2, 3, 4, 6, 7, 8, 9).
count tmp_ledk = hh2kid_mstat hh3kid_mstat hh4kid_mstat hh5kid_mstat hh6kid_mstat hh7kid_mstat hh8kid_mstat (5).

if (tmp_ledk gt 0 and tmp_nledk eq 0) dh16 = 1.
if (tmp_ledk gt 0 and tmp_nledk gt 0) dh16 = 2.
if (tmp_ledk eq 0 and tmp_nledk gt 0) dh16 = 3.
execute.

delete variables tmp_ledk tmp_nledk.

*---
Die übrigen Fälle ohne gültigen Wert auf der Zielvariablen haben fehlende Werte 
oder inkonsistente Angaben auf den Ursprungsvariablen.
*---.

if (dh16 eq -999) dh16 = -32.

*====================================================*
* Erstellung __dh13__ 	LEBENSFORM BEFRAGTE - FAMILIE
*====================================================*.

compute dh13 = 0.
value labels dh13	
    111 "KL1 EHEPAAR" 
    121 "KL2 NEL,B:LED."   
    122 "KL2 NEL,B:NACHEHE" 
    131 "KL3 K.PART(<86)B:LED" 
    132 "KL3 K.PART(<86)B:N.EHE" 
    133 "KL3 K.PART,B:VERH."
    141 "KL4 LAT,B:LED."   
    142 "KL4 LAT,B:NACHEHE"  
    151 "KL5 K.PART,B:LED."  
    152 "KL5 K.PART,B:NACHEHE"
    211 "F1 EHEPAAR+KIND"  
    221 "F2 NEL+KIND,B:LED"   
    222 "F2 NEL+KIND,B:N.EHE"   
    231 "F3 K.PART+K(<86)B:LED" 
    232 "F3 K.PART+K(<86)B:N.EHE" 
    233 "F3 K.PART+K,B:VERH."
    241 "F4 LAT+KIND,B:LED."   
    242 "F4 LAT+KIND,B:N.EHE"  
    251 "F5 K.PART+KIND,B:LED"  
    252 "F5 K.PART+K,B:N.EHE" 
    -32 "NICHT GENERIERBAR".
variable labels dh13 "LEBENSFORM BEFRAGTE - FAMILIE".

if (dh16 eq 0 and dh12 gt 0) dh13 = dh12 + 100.
if (anzkid gt 0) and (dh12 gt 0) dh13 = dh12 + 200.

if (dh12 eq -32) dh13 = -32.
if (dh12 gt 0) and (anzkid eq -32) dh13 = -32.
*========================================================*
* Erstellung __dh14__ 	LEBENSFORM NACH MIKROZENSUS-TYPOLOGIE
*========================================================*.

 * Die amtliche Statistik bietet auf Basis des Mikrozensus Informationen über die Verbreitung verschiedener Lebensformen in der deutschen Bevölkerung.

 * In einem Haushalt können prinzipiell mehrere Lebensformen/Familien bestehen (z.B. die Lebensform der im ALLBUS befragten Person, die Lebensform der nicht-befragten Eltern oder die Lebensform der nicht-befragten Kinder). 
* Da im ALLBUS nicht die komplette Haushaltsstruktur erhoben wird (mit Informationen darüber, wie sämtliche Haushaltsmitglieder miteinander verwandt sind), sondern nur die Verwandtschaftsbeziehung der Haushaltsmitglieder zur befragten Person, 
* lässt sich im ALLBUS die Anzahl an Lebensformen in einem Haushalt in manchen Fällen nicht sicher bestimmen.
 * Beispielsweise lassen sich, sobald mehrere Kinder der Befragten im Haushalt leben, ein Schwiegerkind oder Enkel im Haushalt nicht bestimmten Befragtenkindern als Partner oder Kind zuordnen.
 * Dies wäre aber notwendig, um die Anzahl an Lebensformen im Haushalt zu bestimmen.

 * Aus diesem Grund wird hier lediglich die Lebensform der Befragten rekonstruiert.
 * Lediglich die Gruppe der ledigen Befragten, die im elterlichen Haushalt leben, wird separat gekennzeichnet und kann hierdurch für Analysen auch der Lebensform ihrer Eltern zugewiesen werden.

 * Eine weitere Beschränkung ist, dass der amtlichen Statistik und dem ALLBUS eine unterschiedliche Zählweise von Kindern im Haushalt zu Grunde liegt.
 * Als Kinder zählen im Mikrozensus __ledige Personen__ (ohne Altersbegrenzung) mit __mindestens einem 
Elternteil__ und __ohne Lebenspartner__ bzw. __ohne eigene ledige Kinder__ im Haushalt.

 * Im ALLBUS können zwar ledige und nicht-ledige Kinder der Befragten im Haushalt identifiziert werden, 
* es bestehen aber die genannten Zuordnungsprobleme hinsichtlich der Identifikation von Ehe- oder Lebenspartnern und Kindern der Befragtenkinder (also bspw. Schwiegerkindern und Enkeln der Befragten).

 * Diese Diskrepanz bei der Definition von Kindern im ALLBUS und im Mikrozensus muss bei Vergleichen der Randverteilungen berücksichtigt werden.

 * Die Variable zur Anzahl verschiedener Generationen im Haushalt der Befragten (dh15) kann gegebenenfalls dazu genutzt werden, Diskrepanzen zur Mikrozensus-Typologie abzuschätzen und zu beurteilen.

*-----
 Erstellung einer Hilfsvariablen zur Anzahl der Elternteile im Haushalt
*-----.

count eltern = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin (8, 9).

if (eltern gt 2) eltern = -41.
if (eltern eq 0 and hhmiss gt 0) eltern = -32.
variable labels eltern "ANZAHL ELTERNTEILE IM HAUSHALT".
execute.

*Erstellung von Hilfsvariablen zum Familienstand der Eltern der Befragten.

do repeat #elter = hh2elter hh3elter hh4elter hh5elter hh6elter hh7elter hh8elter /
                #kin = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin /
                #mstat = hh2mstat hh3mstat hh4mstat hh5mstat hh6mstat hh7mstat hh8mstat /
                #e_mstat = hh2elter_mstat hh3elter_mstat hh4elter_mstat hh5elter_mstat hh6elter_mstat hh7elter_mstat hh8elter_mstat.
compute #elter = any(#kin, 8, 9).
if (eltern eq -41) #elter = -41.

compute #e_mstat = $SYSMIS.
if (#elter eq 1) #e_mstat = #mstat.
if (eltern eq -41) #e_mstat = -41.
end repeat.
execute.


*Hilfsvariable: Anzahl verheirateter Elternteile.

count elternvh = hh2elter_mstat hh3elter_mstat hh4elter_mstat hh5elter_mstat hh6elter_mstat hh7elter_mstat hh8elter_mstat (1).

*Hilfsvariablen Familienstand erstes und zweites Elternteil.
*=====SPSS hat keine Äquivalent zu rowfirst/rowlast!!=====.

compute eltermstat1 = max(hh2elter_mstat, hh3elter_mstat, hh4elter_mstat, hh5elter_mstat, hh6elter_mstat, hh7elter_mstat, hh8elter_mstat).
compute eltermstat2 = min(hh2elter_mstat, hh3elter_mstat, hh4elter_mstat, hh5elter_mstat, hh6elter_mstat, hh7elter_mstat, hh8elter_mstat).
value labels eltermstat1 eltermstat2
    -41 "DATENFEHLER"
    -9 "KEINE ANGABE"
    1 "VERHEIRATET"
    2 "VERH.LEBT GETRENNT"
    3 "VERWITWET"
    4 "GESCHIEDEN"
    5 "LEDIG".

*-----
* Erstellung __dh14__ 	LEBENSFORM NACH MIKROZENSUS-TYPOLOGIE
*-----.

compute dh14 = 0.
variable labels dh14 "LEBENSFORM NACH MIKROZENSUS-TYPOLOGIE".
value labels dh14	
    1    "EHEPAAR, KINDERL" 	
    2    "NEL, KINDERL" 
    3    "ALLEIN.LED.KINDERL" 
    4    "ALLEIN.N.LED,KINDERL" 
    5    "EHEPAAR +LED. KIND"	
    6    "NEL +LED.KIND" 
    7    "ALLEINERZ. LED."
    8    "ALLEINERZ.GETR/GESCH"
    9    "ALLEINERZ. VERWITWET" 
    15   "EHEPAAR +LED.K.,B:K."
    16   "NEL +LED. KIND,B:K." 
    17   "ALLEINERZ.LED.,B:K."
    18   "A.-ERZ.GET./GSCH.B:K"	
    19   "ALLEINERZ.VERW.,B:K." 
    -32  "NICHT GENERIERBAR".

if (dh12 eq 11) and any(dh16, 0, 3) dh14 = 1.

do if year gt 1982.
if (partner eq 1) and any(mstat, 2, 3, 4, 5, 7, 8, 9) and any(dh16, 0, 3) dh14 = 2.
if (mstat eq 5) and (partner eq 0) and (ehepartner eq 0) and any(dh16, 0, 3) and (eltern eq 0) dh14 = 3.
if any(mstat, 1, 2, 3, 4, 6, 7, 8, 9) and (partner eq 0) and (ehepartner eq 0) and any(dh16, 0, 3) dh14 = 4.
end if.

do if any(year, 1980, 1982).
if (partner8082 eq 1) and any(mstat, 2, 3, 4, 5) and any(dh16, 0, 3) dh14 = 2.
if (mstat eq 5) and (partner8082 eq 0) and any(dh16, 0, 3) and (eltern eq 0) dh14 = 3.
if any(mstat, 1, 2, 3, 4) and (partner8082 eq 0) and any(dh16, 0, 3) dh14 = 4.
end if.

if (dh12 eq 11) and any(dh16, 1, 2) dh14 = 5.

do if year gt 1982.
if (partner eq 1) and any(mstat, 2, 3, 4, 5, 7, 8, 9) and any(dh16, 1, 2) dh14 = 6.
if (mstat eq 5) and (partner eq 0) and (ehepartner eq 0) and any(dh16, 1, 2) and (year gt 1982) dh14 = 7.
if any(mstat, 2, 4, 7, 9) and (partner eq 0) and (ehepartner eq 0) and any(dh16, 1, 2) dh14 = 8.
if any(mstat, 3, 8) and (partner eq 0) and (ehepartner eq 0) and any(dh16, 1, 2) dh14 = 9.
if (mstat eq 5) and (partner eq 0) and (ehepartner eq 0) and any(dh16, 0, 3) and (eltern gt 0) and not sysmis(eltern) dh14 = 10.
end if.

do if any(year, 1982, 1980).
if (partner8082 eq 1) and any(mstat, 2, 3, 4, 5) and any(dh16, 1, 2) dh14 = 6.
if (mstat eq 5) and (partner8082 eq 0) and any(dh16, 1, 2) dh14 = 7.
if any(mstat, 2, 4, 7, 9) and (partner8082 eq 0) and any(dh16, 1, 2) dh14 = 8.
if any(mstat, 3, 8) and (partner8082 eq 0)and any(dh16, 1, 2) dh14 = 9.
if (mstat eq 5) and (partner8082 eq 0) and any(dh16, 0, 3) and (eltern gt 0) and not sysmis(eltern) dh14 = 10.
end if.

if (mstat lt 0) or (dh16 eq -32) or any(eltern, -32, -41) dh14 = -32.
if (dh14 eq 10) and (eltern lt 0) dh14 = -32. /*Fehlende Werte bei Angaben zu Eltern.
if (dh14 eq 10) and ((eltermstat1 eq -9) or (eltermstat2 eq -9)) dh14 = -32. /*Familienstand der Eltern ist unbekannt.
if (dh14 eq 10) and (eltern eq 1) and (eltermstat1 eq 1) dh14 eq -32. /*1 Elternteil, aber Familienstand "Verheiratet, zusammenlebend".

if (dh14 eq 10) and (eltern eq 2) and (elternvh eq 2) dh14 = 15.
if (dh14 eq 10) and (eltern eq 2) and any(elternvh, 0, 1) dh14 = 16.
if (dh14 eq 10) and (eltern eq 1) and (eltermstat1 eq 5) dh14 = 17.
if (dh14 eq 10) and (eltern eq 1) and any(eltermstat1, 2, 4, 7, 9) dh14 = 18.
if (dh14 eq 10) and (eltern eq 1) and any(eltermstat1, 3, 8) dh14 = 19.

*-----
* Die übrigen Fälle ohne gültigen Wert auf der Zielvariablen haben fehlende Werte oder inkonsistente Angaben auf den Ursprungsvariablen, oder
* Merkmalskombinationen, die für die Mikrozensustypologie nicht definiert sind.
*-----.

if (dh14 eq 0) dh14 = -32.
execute.

*========================================================*
* Erstellung __dh15__ MEHRGENERATIONEN-HAUSHALT
*========================================================*.

*-----
* Erstellung von Hilfsvariablen zu Angehörigen verschiedener Generationen im Haushalt
*-----.

count tmp_parent = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin (8, 9, 10).
compute parent_gen = tmp_parent gt 0.
if (hhmiss gt 0) parent_gen = -32.
variable labels parent_gen "ELTERNGENERATION IM HH (BEFRAGTENPERSPEKTIVE)".

count tmp_kid = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin (3, 4, 11). 
compute kid_gen = tmp_kid gt 0. /*Kinder & Schwiegerkinder.
if (hhmiss gt 0) kid_gen = -32.
variable labels kid_gen "KINDGENERATION IM HH (BEFRAGTENPERSPEKTIVE)".

compute grandch_gen = any(7, hh2kin, hh3kin, hh4kin, hh5kin, hh6kin, hh7kin, hh8kin).
if (hhmiss gt 0) grandch_gen = -32.
variable labels grandch_gen "ENKEL IM HH (BEFRAGTENPERSPEKTIVE)".

count tmp_gramps = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin (13, 14). /* Großeltern der Befragten oder der Partner.
compute gramps_gen = tmp_gramps gt 0.
if (hhmiss gt 0) gramps_gen = -32.
variable labels gramps_gen "GROSSELTERNGENERATION IM HH (BEFRAGTENPERSPEKTIVE)".

count tmp_resp = hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin (1, 2, 17, 5, 6, 12). /*Partner, Geschwister, Schwager.
compute resp_gen = tmp_resp gt 0.
if (hhmiss gt 0) resp_gen = -32.
variable labels resp_gen "BEFRAGTENGENERATION IM HH".

count tmp_other =  hh2kin hh3kin hh4kin hh5kin hh6kin hh7kin hh8kin (15, 16).
compute other_pers = tmp_other gt 0.
if (hhmiss gt 0) other_pers = -32.
variable labels other_pers "ANDERE (VERWANDT/NICHT-VERWANDT) IM HH (BEFRAGTENPERSPEKTIVE)".

count tmp = parent_gen kid_gen grandch_gen gramps_gen (1).
compute anz_gen = tmp + 1.
if (hhmiss gt 0 ) anz_gen = -32.

value labels parent_gen kid_gen grandch_gen gramps_gen resp_gen other_pers anz_gen
    -10 "TNZ: FILTER"
    -32 "NICHT GENERIERBAR"
    -41 "DATENFEHLER".

*-----
* Erstellung __dh15__ MEHRGENERATIONEN-HAUSHALT
*-----.

compute dh15 = $SYSMIS.
if (dh01 eq 2) dh15 = 10.
if (anz_gen eq 1) and (resp_gen eq 1) dh15 eq 11.
if (anz_gen eq 2) dh15 = 20.
if (anz_gen eq 3) dh15 = 30.
if (anz_gen eq 4) dh15 = 40.
if (anz_gen eq 1) and (other_pers eq 1) dh15 = 60. /*Wenn andere im Haushalt wohnen und nur eine Generation, wird auf WG kodiert. 
if (hhmiss gt 0) dh15 = -32.

variable labels dh15 "MEHRGENERATIONEN-HAUSHALT".
value labels dh15  
    10 "EINPERSONEN-HH" 
    11 "EIN-GENERATIONEN-HH" 
    20 "ZWEI-GENERATIONEN-HH" 
    30 "DREI-GENERATIONEN-HH" 
    40 "VIER-GENERATIONEN-HH" 
    60 "WG VERW./NICHT-VERW." 
    -32 "NICHT GENERIERBAR".

*========================================================*
* Erstellung __dh17__ ALTER JUENGSTES HAUSHALTSMITGLIED
*========================================================*.

recode hh2age hh3age hh4age hh5age hh6age hh7age hh8age (-10 = SYSMIS).
compute dh17 = min(age, hh2age, hh3age, hh4age, hh5age, hh6age, hh7age, hh8age).
if (dh04 eq -32) dh17 = -32.
recode hh2age hh3age hh4age hh5age hh6age hh7age hh8age (SYSMIS = -10).
variable labels dh17 "ALTER JUENGSTES HAUSHALTSMITGLIED".
value labels dh17
    -32 "NICHT GENERIERBAR"
    0    "UNTER 1 JAHR".

execute.

missing values dh12 dh13 dh14 dh15 dh16 dh17 (low to -1).

*========================================================*
* Erstellten Datensatz abspeichern
*========================================================*.

delete variables hh2kid hh3kid hh4kid hh5kid hh6kid hh7kid hh8kid hh2kid_mstat
hh3kid_mstat hh4kid_mstat hh5kid_mstat hh6kid_mstat hh7kid_mstat
hh8kid_mstat anzkid eltern hh2elter hh2elter_mstat hh3elter
hh3elter_mstat hh4elter hh4elter_mstat hh5elter hh5elter_mstat
hh6elter hh6elter_mstat hh7elter hh7elter_mstat hh8elter
hh8elter_mstat elternvh eltermstat1 eltermstat2 tmp_parent parent_gen
tmp_kid kid_gen grandch_gen tmp_gramps gramps_gen tmp_resp resp_gen
tmp_other other_pers tmp anz_gen.

*Dateinamen anpassen.
*SAVE OUTFILE='ZAxxxx_famtyp.sav'
  /COMPRESSED.