* Encoding: UTF-8. 
***************************************************************
* Syntaxfile, das ESeG des Befragten, des Ehepartners,
* des Lebenspartners, des Vaters und der Mutter fuer 
* ALLBUS 2012 (ZA4614, mit Zusatzdatensatz ZA4618)
* ALLBUS 2014 (ZA5240)
* ALLBUS 2016 (ZA5250), oder
* ALLBUS-Kumulation 1980-2016 (ZA4586) generiert.
*
* Diese Syntax ist angelehnt an die SPSS-Routine von 
* Jeanette Bohr (2018) und berücksichtigt die 
* ESeG-Revisionen von 2014 und 2016.
*
* Jeanette Bohr 2018: EU-AES Tools: Implementation of 
* the European Socioeconomic Groups Classification (ESeG) 
* using Adult Education Survey Microdata, GESIS Papers, 
* Köln: GESIS - Leibniz-Institut für Sozialwissenschaften.
*
* Weitere Informationen siehe:
* Sarah Thiesen und Sonja Schulz 2019: Bildung der European 
* Socioeconomic Groups (ESeG) im ALLBUS, GESIS-Servicedokument, 
* Köln: GESIS - Leibniz-Institut für Sozialwissenschaften.
*
* (c) GESIS 2019
* GESIS - Leibniz-Institut für Sozialwisschenschaften
* Datenarchiv für Sozialwissenschaften (DAS)
* https://www.gesis.org/allbus
***************************************************************

*Bitte Pfad und Dateinamen des verwendeten ALLBUS-Datensatzes anpassen:
local data "<Pfad>\ZAxxxx_vx-x-x.dta"

*Zusatzdatensatz zum ALLBUS 2012
*Falls ALLBUS 2012 verwendet wird, bitte Pfad anpassen:
local zusatz "<Pfad>\ZA4618_v1.0.0.dta"

*Bitte Pfad und Dateinamen der Ausgabedatei anpassen:
local outfile "<Pfad>\ZAxxxx_eseg.dta"

**************************************
*Datensatz öffnen.
use "`data'", clear

***Vorbereitung.

*ALLBUS 2012/2014 - Variable ZA-Nummer umbenennen.

capture confirm variable v1
if !_rc {
    rename v1 za_nr
}
capture confirm variable V1
if !_rc {
    rename V1 za_nr
}

*** ALLBUS 2012: Zusatzdatensatz mergen und auf neue Variablennamen umbenennen.

capture assert za_nr == 4614

if !_rc {
sort v2
save "`outfile'", replace 
use "`zusatz'", clear 
sort v2 
save "`zusatz'", replace
use "`outfile'", clear
merge v2 using "`zusatz'"
describe 
tab _merge

rename v245 work /*BEFRAGTE<R> BERUFSTAETIG?*/
rename v246 dw01 /*BEFR.: JETZIGE BERUFLICHE STELLUNG*/
rename v262 dw01a /*BEFR.: LETZTE BERUFLICHE STELLUNG*/
rename v259 dw03 /*BEFR.: STATUS DER NICHTERWERBSTAETIGKEIT*/
rename v905 isco08 /*BEFR.: JETZIGER BERUF; ISCO 2008 */
rename v911 isco08a /*BEFR.: LETZTER BERUF; ISCO 2008 */
rename v296 scwork /*GEGENWAERTIGER EHEP. BERUFSTAETIG?*/
rename v297 scdw01 /*GEGENW.EHEP.: JETZIGE BERUFL. STELLUNG*/
rename v299 scdw03 /*EHEP.: STATUS DER NICHTERWERBSTAETIGKEIT*/
rename v917 scisco08 /*GEGENW.EHEP.: JETZIGER BERUF; ISCO 2008*/
rename v274 mstat /*FAMILIENSTAND, BEFRAGTE<R>*/
rename v323 pwork /*LEBENSPARTNER: BERUFSTAETIG?*/
rename v324 pdw01 /*LEBENSPARTNER: JETZIGE BERUFL.STELLUNG*/
rename v326 pdw03 /*LEBENSP: STATUS D.NICHTERWERBSTAETIGKEIT*/
rename v923 pisco08 /*LEBENSPARTNER: JETZIGER BERUF; ISCO 2008*/
rename v300 dp01 /*HABEN SIE EINEN FESTEN LEBENSPARTNER?*/
rename v328 fdw01 /*VATER: BERUFLICHE STELLUNG*/
rename v929 fisco08 /*VATER: BERUF; ISCO 2008*/
rename v330 mdw01 /*MUTTER: BERUFLICHE STELLUNG */
rename v935 misco08 /*MUTTER: BERUF, DAMALS; ISCO 2008*/
}

*** ALLBUS 2014 - Auf neue Variablennamen umbenennen
capture assert za_nr == 5240
if !_rc {
rename V103 work /*BEFRAGTE<R> BERUFSTAETIG?*/
rename V104 dw01 /*BEFR.: JETZIGE BERUFLICHE STELLUNG*/
rename V142 dw01a /*BEFR.: LETZTE BERUFLICHE STELLUNG*/
rename V139 dw03 /*BEFR.: STATUS DER NICHTERWERBSTAETIGKEIT*/
rename V111 isco08 /*BEFR.: JETZIGER BERUF; ISCO 2008 */
rename V149 isco08a /*BEFR.: LETZTER BERUF; ISCO 2008 */
rename V319 scwork /*GEGENWAERTIGER EHEP. BERUFSTAETIG?*/
rename V320 scdw01 /*GEGENW.EHEP.: JETZIGE BERUFL. STELLUNG*/
rename V332 scdw03 /*EHEP.: STATUS DER NICHTERWERBSTAETIGKEIT*/
rename V327 scisco08 /*GEGENW.EHEP.: JETZIGER BERUF; ISCO 2008*/
rename V297 mstat /*FAMILIENSTAND, BEFRAGTE<R>*/
rename V356 pwork /*LEBENSPARTNER: BERUFSTAETIG?*/
rename V357 pdw01 /*LEBENSPARTNER: JETZIGE BERUFL.STELLUNG*/
rename V369 pdw03 /*LEBENSP: STATUS D.NICHTERWERBSTAETIGKEIT*/
rename V364 pisco08 /*LEBENSPARTNER: JETZIGER BERUF; ISCO 2008*/
rename V333 dp01 /*HABEN SIE EINEN FESTEN LEBENSPARTNER?*/
rename V387 fdw01 /*VATER: BERUFLICHE STELLUNG*/
rename V394 fisco08 /*VATER: BERUF; ISCO 2008*/
rename V399 mdw01 /*MUTTER: BERUFLICHE STELLUNG */
rename V406 misco08 /*MUTTER: BERUF, DAMALS; ISCO 2008*/
}

*Missing Values auf negative Werte recodieren.
recode isco08 10004=-33 10009=-9 0=-10
recode isco08a 10004=-33 10009=-9 0=-10
recode scisco08 10004=-33 10009=-9 0=-10
recode pisco08 10004=-33 10009=-9 0=-10
recode fisco08 10004=-33 10009=-9 0=-10
recode misco08 10004=-33 10009=-9 0=-10 10006=-50
recode dw01 99=-9 0=-10
recode dw01a 99=-9 0=-10
recode scdw01 99=-9 0=-10
recode pdw01 99=-9 0=-10
recode mdw01 0=-10 91=-53 93=-54 94=-53 95=-54 98=-8 99=-9
recode mstat 99=-9 0=-10
recode dw03 0=-10 9=-9
recode scdw03 0=-10 9=-9
recode pdw03 0=-10 9=-9
recode work 9=-9 99=-9
recode scwork 0=-10 9=-9 99=-9
recode pwork 0=-10 9=-9 99=-9
recode dp01 0=-10 9=-9
recode fdw01 0=-10 91=-50 92=-51 93=-52 94=-54 95=-53 96=-55 98=-8 99=-9 if za_nr == 4614
recode fdw01 0=-10 90=-50 91=-51 92=-52 93=-54 94=-53 95=-55 98=-8 99=-9 if za_nr == 5240

*ISCO08 auf die ersten beiden Stellen kürzen.
local iscos  isco08 isco08a scisco08 pisco08 fisco08 misco08
foreach var of local iscos {
	gen `var'neu = floor(`var' / 100)
	replace `var'neu = `var' if `var' <= -1
}

*Variable selbstständig/abhängig beschäftigt.
local person `" "" "sc" "p" "f" "m" "'
foreach var of local person {
	egen `var'STA = anymatch(`var'dw01), values(4, 5, 6, 7)
	replace `var'STA = `var'dw01 if `var'dw01 <= -1
	replace `var'STA = -32 if `var'dw01 == 9
}
egen STAa = anymatch(dw01a), values(4, 5, 6, 7)
replace STAa = dw01a if dw01a <= -1
replace STAa = -32 if dw01a == 9

label define sta 0 "Selbstständig" 1 "Angestellt" -10 "Trifft nicht zu" -9 "Keine Angabe" -32 "Nicht generierbar"
label values STA STAa scSTA pSTA fSTA mSTA sta

**************************************

**************ESeG********************

**** Gruppen 1 bis 7.****

foreach var of local person {
gen `var'eseg = -1

*** 1 Managers.
replace `var'eseg = 10 if (`var'isco08neu >= 10 & `var'isco08neu <= 14)
*1.1 Higher managerial self-employed (ISCO 11, 12, 13 and STATUS=se) 
replace `var'eseg = 11 if (`var'isco08neu >= 11 & `var'isco08neu <= 13 & `var'STA == 0)
*1.2 Lower managerial self-employed (ISCO 14 and STATUS=se) 
replace `var'eseg = 12 if (`var'isco08neu == 14 & `var'STA == 0)
*1.3 Higher managerial employees (ISCO 11, 12, 13 and 01 and STATUS=e) 
replace `var'eseg = 13 if (((`var'isco08neu >= 11 & `var'isco08neu <= 13) | (`var'isco08neu == 01)) & `var'STA == 1)
*1.4 Lower managerial employees (ISCO 14 and STATUS=e) 
replace `var'eseg = 14 if (`var'isco08neu == 14 & `var'STA == 1)

*** 2 Professionals: ISCO = 20, 21, 22, 23, 24, 25, 26
replace `var'eseg = 20 if (`var'isco08neu == 20)
*2.1 Science, engineering and information and communications technology (ICT) professionnals (ISCO 21,25) 
replace `var'eseg = 21 if (`var'isco08neu == 21 | `var'isco08neu == 25) 
*2.2 Health professionals (ISCO 22) 
replace `var'eseg = 22 if (`var'isco08neu == 22)
*2.3 Business and administration professionals (ISCO 24) 
replace `var'eseg = 23 if (`var'isco08neu == 24)
*2.4 Legal, social and cultural professionals (ISCO 26) 
replace `var'eseg = 24 if (`var'isco08neu == 26)
*2.5 Teaching professionals (ISCO 23) 
replace `var'eseg = 25 if (`var'isco08neu == 23)

*** 3 Technicians and other professional employees: ISCO = 02, 31, 32, 33, 34, 35.
replace `var'eseg = 30 if (`var'isco08neu == 30 & `var'STA == 1)
*3.1 Science, engineering and ICT technicians and associated professionals (ISCO 31, 35) 
replace `var'eseg = 31 if ((`var'isco08neu == 31 | `var'isco08neu == 35) & `var'STA == 1)
*3.2 Health associate professionals (ISCO 32) 
replace `var'eseg = 32 if (`var'isco08neu == 32 & `var'STA == 1)
*3.3 Business and administration associate professionals (ISCO 33) 
replace `var'eseg = 33 if (`var'isco08neu == 33 & `var'STA == 1)
*3.4 Legal, social and cultural associate professionals (ISCO 34) 
replace `var'eseg = 34 if (`var'isco08neu == 34 & `var'STA == 1)
*3.5 Non-commissioned armed forces officers (ISCO 02 ) 
replace `var'eseg = 35 if (`var'isco08neu == 02 & `var'STA == 1)

*** 4 Small entrepreneurs: ISCO = 3, 4, 5, 6, 7, 8, 9, pSTA = 0.
replace `var'eseg = 40 if (`var'isco08neu >= 30 & `var'isco08neu <= 96) & (`var'STA == 0)
*4.1 Self-employed agricultural and related workers  (ISCO 6, 92) 
replace `var'eseg = 41 if ((`var'isco08neu >= 60 & `var'isco08neu <= 63) | `var'isco08neu == 92) & `var'STA == 0
*4.2 Technicians, clerical support, services and sales self employed workers (ISCO 3, 4, 5) 
replace `var'eseg = 42 if (`var'isco08neu >= 31 & `var'isco08neu <= 54 & `var'STA == 0)
*4.3 Craft and related trades self employed workers (ISCO 7, 8, 9, except 92) 
replace `var'eseg = 43 if (`var'isco08neu >= 71 & `var'isco08neu <= 96 & `var'isco08neu != 92 & `var'STA == 0)

*** 5 Clerks and skilled service employees: ISCO = 41, 42, 43, 44, 53, 54, 03, 04.
replace `var'eseg = 50 if (`var'isco08neu == 40) & (`var'STA == 1)
*5.1 General and numerical clerks and other clerical support employees (ISCO 41, 43, 44) 
replace `var'eseg = 51 if (`var'isco08neu == 41 | `var'isco08neu == 43 | `var'isco08neu == 44) & `var'STA == 1
*5.2 Customer services clerks (ISCO 42) 
replace `var'eseg = 52 if (`var'isco08neu == 42 & `var'STA == 1)
*5.3 Personal care employees (ISCO 53) 
replace `var'eseg = 53 if (`var'isco08neu == 53 & `var'STA == 1)
*5.4 Armed forced occupations and protective service employees (ISCO 03 and ISCO 54) 
replace `var'eseg = 54 if (`var'isco08neu == 54 | `var'isco08neu == 03 | `var'isco08neu == 04) & `var'STA == 1

*** 6 Skilled industrial employees: ISCO = 71, 72, 73, 74, 75, 81, 82, 83.
replace `var'eseg = 60 if (`var'isco08neu == 70 | `var'isco08neu == 80) & `var'STA == 1
*6.1 Building and related trade employees (ISCO 71) 
replace `var'eseg = 61 if (`var'isco08neu == 71 & `var'STA == 1)
*6.2 Food processing, wood working, garment employees (ISCO 75) 
replace `var'eseg = 62 if (`var'isco08neu == 75 & `var'STA == 1)
*6.3 Metal, machinery, handicraft, printing, electrical and electronic trades employees (ISCO 72, 73, 74) 
replace `var'eseg = 63 if (`var'isco08neu >= 72 & `var'isco08neu <= 74 & `var'STA == 1)
*6.4 Stationary plant and machine operators and assemblers (ISCO 81, 82) 
replace `var'eseg = 64 if (`var'isco08neu == 81 | `var'isco08neu == 82) & `var'STA == 1
*6.5 Drivers (ISCO 83) 
replace `var'eseg = 65 if (`var'isco08neu == 83 & `var'STA == 1)

*** 7 Lower status employees: ISCO = 51, 52, 60, 61, 62, 63, 90, 91, 92, 93, 94, 95, 96
replace `var'eseg = 70 if (`var'isco08neu == 90) & (`var'STA == 1)
*7.1 Personal services and sales employees (ISCO 51, 52) 
replace `var'eseg = 71 if (`var'isco08neu == 51 | `var'isco08neu == 52) & `var'STA == 1
*7.2 Blue collar employees and food preparation assistants in elementary occupations (ISCO 93, 94, 96) 
replace `var'eseg = 72 if (`var'isco08neu == 93 | `var'isco08neu == 94 | `var'isco08neu == 96) & `var'STA == 1
*7.3 Cleaners and helpers and services employees in elementary occupations (ISCO 91, 95) 
replace `var'eseg = 73 if (`var'isco08neu == 91 | `var'isco08neu == 95) & `var'STA == 1
*7.4 Agricultural employees (ISCO 6, 92) 
replace `var'eseg = 74 if (`var'isco08neu == 60 | `var'isco08neu == 61 | `var'isco08neu == 62 | `var'isco08neu == 63 | `var'isco08neu == 92) & `var'STA == 1
}

***Befragter: Arbeitslose

replace eseg = 10 if (isco08aneu >= 10 & isco08aneu <= 14) & (dw03 == 3)
replace eseg = 11 if (isco08aneu >= 11 & isco08aneu <= 13 & STAa == 0 & dw03 == 3)
replace eseg = 12 if (isco08aneu == 14 & STAa == 0 & dw03 == 3)
replace eseg = 13 if (((isco08aneu >= 11 & isco08aneu <= 13) | (isco08aneu == 01)) & STAa == 1 & dw03 == 3)
replace eseg = 14 if (isco08aneu == 14 & STAa == 1 & dw03 ==3)

replace eseg = 20 if (isco08aneu == 20 & dw03 == 3)
replace eseg = 21 if (isco08aneu == 21 | isco08aneu == 25) & dw03 == 3
replace eseg = 22 if (isco08aneu == 22 & dw03 == 3)
replace eseg = 23 if (isco08aneu == 24 & dw03 == 3)
replace eseg = 24 if (isco08aneu == 26 & dw03 == 3)
replace eseg = 25 if (isco08aneu == 23 & dw03 == 3)

replace eseg = 30 if (isco08aneu == 30 & STAa == 1 & dw03 == 3)
replace eseg = 31 if ((isco08aneu == 31 | isco08aneu == 35) & STAa == 1 & dw03 == 3)
replace eseg = 32 if (isco08aneu == 32 & STAa == 1 & dw03 == 3)
replace eseg = 33 if (isco08aneu == 33 & STAa == 1 & dw03 == 3)
replace eseg = 34 if (isco08aneu == 34 & STAa == 1 & dw03 == 3)
replace eseg = 35 if (isco08aneu == 02 & STAa == 1 & dw03 == 3)

replace eseg = 40 if (isco08aneu >= 30 & isco08aneu <= 96) & (STAa == 0) & dw03 == 3
replace eseg = 41 if ((isco08aneu >= 60 & isco08aneu <= 63) | isco08aneu == 92) & STAa == 0 & dw03 == 3
replace eseg = 42 if (isco08aneu >= 31 & isco08aneu <= 54 & STAa == 0 & dw03 == 3)
replace eseg = 43 if (isco08aneu >= 71 & isco08aneu <= 96 & isco08aneu != 92 & STAa == 0 & dw03 == 3)

replace eseg = 50 if (isco08aneu == 40) & (STAa == 1) & (dw03 == 3)
replace eseg = 51 if (isco08aneu == 41 | isco08aneu == 43 | isco08aneu == 44) & STAa == 1 & dw03 == 3
replace eseg = 52 if (isco08aneu == 42 & STAa == 1 & dw03 == 3)
replace eseg = 53 if (isco08aneu == 53 & STAa == 1 & dw03 == 3)
replace eseg = 54 if (isco08aneu == 54 | isco08aneu == 03 | isco08aneu == 04) & STAa == 1 & dw03 == 3

replace eseg = 60 if (isco08aneu == 70 | isco08aneu == 80) & STAa == 1 & dw03 == 3
replace eseg = 61 if (isco08aneu == 71 & STAa == 1 & dw03 == 3)
replace eseg = 62 if (isco08aneu == 75 & STAa == 1 & dw03 == 3)
replace eseg = 63 if (isco08aneu >= 72 & isco08aneu <= 74 & STAa == 1 & dw03 == 3)
replace eseg = 64 if (isco08aneu == 81 | isco08aneu == 82) & STAa == 1 & dw03 == 3
replace eseg = 65 if (isco08aneu == 83 & STAa == 1 & dw03 == 3)

replace eseg = 70 if (isco08aneu == 90) & (STAa == 1) & dw03 == 3
replace eseg = 71 if (isco08aneu == 51 | isco08aneu == 52) & STAa == 1 & dw03 == 3
replace eseg = 72 if (isco08aneu == 93 | isco08aneu == 94 | isco08aneu == 96) & STAa == 1 & dw03 == 3
replace eseg = 73 if (isco08aneu == 91 | isco08aneu == 95) & STAa == 1 & dw03 == 3
replace eseg = 74 if (isco08aneu == 60 | isco08aneu == 61 | isco08aneu == 62 | isco08aneu == 63 | isco08aneu == 92) & STAa == 1 & dw03 == 3

**** Gruppen 8 und 9.****

***Befragter:***
*** 8 Retired persons.
replace eseg = 80 if dw03 == 2
*8.1 Retired Managers.
replace eseg = 81 if (isco08aneu == 01 | (isco08aneu >= 10 & isco08aneu <= 14)) & dw03 == 2
*8.2 Retired professionals.
replace eseg = 82 if (isco08aneu >= 20 & isco08aneu <= 26 & dw03 == 2)
*8.3 Retired technicians and associate professionals.
replace eseg = 83 if (isco08aneu == 02 | (isco08aneu >= 30 & isco08aneu <= 35)) & STAa == 1 & dw03 == 2
*8.4 Retired small entrepreneurs.
replace eseg = 84 if (isco08aneu >= 30 & isco08aneu <= 96 & STAa == 0 & dw03 == 2)
*8.5 Retired skilled service workers .
replace eseg = 85 if (isco08aneu == 03 | (isco08aneu >= 40 & isco08aneu <= 44) | isco08aneu == 53 | isco08aneu == 54) & STAa == 1 & dw03 == 2
*8.6 Retired skilled blue-collars .
replace eseg = 86 if (isco08aneu >= 70 & isco08aneu <= 83) & STAa == 1 & dw03 == 2
*8.7 Retired less skilled workers .
replace eseg = 87 if (isco08aneu == 51 | isco08aneu == 52 | (isco08aneu >= 60 & isco08aneu <= 63) | (isco08aneu >= 90 & isco08aneu <= 96)) & STAa == 1 & dw03 == 2

*** 9 Other persons outside the labor force.
*9.1 Student.
replace eseg = 91 if (dw03 == 1)
*9.2 Permanently disabled: Kann nicht gebildet werden.
*9.9 Other persons outside the labor force not elsewhere classified
replace eseg = 99 if (dw03 >= 4 & dw03 <= 6)

***Ehepartner und Lebenspartner:***
local person2 sc p
foreach var of local person2 {
*** 8 Retired persons.
replace `var'eseg = 80 if `var'dw03 == 2

*** 9 Other persons outside the Labour Force 
*9.1 Student.
replace `var'eseg = 91 if `var'dw03 == 1
*9.2 Permanently disabled: Kann nicht gebildet werden.
*9.9  Other persons outside the labor force not elsewhere classified
replace `var'eseg = 99 if (`var'dw03 >= 4 & `var'dw03 <= 6)
}

***Vater:***
replace feseg = 80 if (fdw01 == -50)
replace feseg = 90 if (fdw01 == -53)

***Mutter:***
replace meseg = 900 if (mdw01 == -53 | misco08 == -50)

**** Gruppe 0: Persons in the labour force, whose occupation or status in employment is not known ****
local person3 `" "" "sc" "p" "'
foreach var of local person3 {
replace `var'eseg = 01 if (`var'work == 1 | `var'work == 2) & `var'eseg == -1
replace `var'eseg = 02 if (`var'dw03 == 3) & `var'eseg == -1
}

replace feseg = 01 if fisco08 == -33 | (fdw01 > 0 & feseg == -1)
replace feseg = 02 if fdw01 == -51

replace meseg = 01 if (mdw01 > 0 & meseg == -1)

**** Missing Values ****
foreach var of local person3 {
replace `var'eseg = -32 if `var'eseg == -1 & (`var'dw01 == -9 | `var'work == -9 | `var'dw03 == -9)
}
replace sceseg = -10 if (mstat != 1) & (mstat != 6)
replace peseg = -10 if (dp01 != 1)
replace feseg = -32 if feseg == -1 & (fdw01 == -9 | fdw01 == -8 | fdw01 == -54 | fdw01 == -55 | fdw01 == -52)
replace meseg = -32 if meseg == -1 & (mdw01 == -9 | mdw01 == -8 | mdw01 == -54)

**** Kumulation: ESeG vor 2012 nicht generierbar ****

capture confirm variable year
if !_rc {
    foreach var of local person {
        replace `var'eseg = -34 if (year < 2012)
    }
}

**** Labels ****
label variable eseg "BEFR.: SOZIO-OEKONOMISCHE GRUPPE (ESEG)"
label variable sceseg "GEGENW.EHEP.: SOZIO-OEKON.GRUPPE (ESEG)"
label variable peseg "LEBENSPARTNER: SOZIO-OEKON.GRUPPE (ESEG)"
label variable feseg "VATER: SOZIO-OEKONOMISCHE GRUPPE (ESEG)"
label variable meseg "MUTTER: SOZIO-OEKONOMISCHE GRUPPE (ESEG)"

#delimit ;
label define eseg1
01 "EMPLOYED, NO GROUP"
02 "UNEMPLOYED, NO GROUP"
10 "MANAGERS" 
11 "HIGHER MG. SELF-EMP."
12 "LOWER MG. SELF-EMP." 
13 "HIGHER MG. EMPLOYEES" 
14 "LOWER MG. EMPLOYEES" 
20 "PROFESSIONALS"
21 "SCIENCE/ICT PROF."
22 "HEALTH PROFESSIONALS" 
23 "BUSINESS PROF." 
24 "LEGAL/SOCIAL PROF." 
25 "TEACHING PROF." 
30 "PROFESSIONAL EMP."
31 "TECHNICIANS"
32 "HEALTH ASS. PROF." 
33 "BUSINESS ASS. PROF." 
34 "LEGAL/SOCIAL ASS.PRO" 
35 "NCOS"
40 "SMALL ENTREPRENEURS" 
41 "AGRIC. SELF-EMPLOYED" 
42 "SELF-EMPLOYED TECHN." 
43 "CRAFT ETC. SELF-EMP." 
50 "CLERKS/SERVICE EMP."
51 "GENERAL CLERKS" 
52 "CUSTOMER SERVICE CL." 
53 "PERSONAL CARE EMP." 
54 "PROTECTIVE SERVICS" 
60 "INDUSTRIAL EMPLOYEES"
61 "BUILDING EMPLOYEES" 
62 "FOOD PROCESSING ETC." 
63 "METAL/MACHINERY ETC." 
64 "STATIONARY PLANT OP." 
65 "MOBILE PLANT OP." 
70 "LOWER STATUS EMP." 
71 "SERVICE/SALES EMP." 
72 "BLUE COLLAR EMP." 
73 "CLEANERS AND HELPERS" 
74 "AGRICULTURAL EMP." 
80 "RETIRED PERSONS"
81 "RETIRED MANAGERS"
82 "RETIRED PROF."
83 "RETIRED TECHNICIANS"
84 "R. ENTREPRENEURS"
85 "RETIRED CLERKS"
86 "R. INDUSTRIAL EMP."
87 "R. LOWER STATUS EMP."
90 "OTHERS OUTSIDE LF"
91 "STUDENTS" 
99 "OTHER INACTIVE"
-34 "NICHT ENTHALTEN"
-32 "NICHT GENERIERBAR"
-10 "TNZ: FILTER";

label define eseg2
01 "EMPLOYED, NO GROUP"
10 "MANAGERS" 
11 "HIGHER MG. SELF-EMP."
12 "LOWER MG. SELF-EMP." 
13 "HIGHER MG. EMPLOYEES" 
14 "LOWER MG. EMPLOYEES" 
20 "PROFESSIONALS"
21 "SCIENCE/ICT PROF."
22 "HEALTH PROFESSIONALS" 
23 "BUSINESS PROF." 
24 "LEGAL/SOCIAL PROF." 
25 "TEACHING PROF." 
30 "PROFESSIONAL EMP."
31 "TECHNICIANS"
32 "HEALTH ASS. PROF." 
33 "BUSINESS ASS. PROF." 
34 "LEGAL/SOCIAL ASS.PRO" 
35 "NCOS"
40 "SMALL ENTREPRENEURS" 
41 "AGRIC. SELF-EMPLOYED" 
42 "SELF-EMPLOYED TECHN." 
43 "CRAFT ETC. SELF-EMP." 
50 "CLERKS/SERVICE EMP."
51 "GENERAL CLERKS" 
52 "CUSTOMER SERVICE CL." 
53 "PERSONAL CARE EMP." 
54 "PROTECTIVE SERVICS" 
60 "INDUSTRIAL EMPLOYEES"
61 "BUILDING EMPLOYEES" 
62 "FOOD PROCESSING ETC." 
63 "METAL/MACHINERY ETC." 
64 "STATIONARY PLANT OP." 
65 "MOBILE PLANT OP." 
70 "LOWER STATUS EMP." 
71 "SERVICE/SALES EMP." 
72 "BLUE COLLAR EMP." 
73 "CLEANERS AND HELPERS" 
74 "AGRICULTURAL EMP." 
900 "NON-EMPLOYED PERSONS"
-32 "NICHT GENERIERBAR"
-34 "NICHT ENTHALTEN";
#delimit cr

label values eseg sceseg peseg feseg eseg1
label values meseg eseg2

**** Aufraeumen und speichern ****

drop isco08neu isco08aneu scisco08neu pisco08neu fisco08neu misco08neu STA STAa scSTA pSTA fSTA mSTA
tab eseg
tab sceseg
tab peseg
tab feseg
tab meseg

*Speichern.
save "`outfile'", replace