*========================================================================================================
*Die folgende Syntax wurde ursprünglich von Dr. Walter Funk für das Statistikprogramm SPSS erstellt und im Jahr (1989) zuerst publiziert.
*Die Syntax wurde in den Folgejahren für Änderungen am ALLBUS-Frageprogramm adaptiert 
*(z.B. Gleichsetzung von eingetragenen Lebensgemeinschaften mit verheirateten Ehepaaren).
*Mit diesem Stata Do-File kann die Haushalts- und Familientypologie nach Porst (1984) anhand von neueren ALLBUS Querschnitten rekonstruiert werden.
*========================================================================================================



********************************************************************************
**                        Stata-Syntax zur Bildung der                        **
**              Haushalts- und Familientypologie nach Porst (1984),           **
**          basierend auf einer SPSS-Syntax von Dr. Walter Funk (1989)        **     
********************************************************************************
* Funk, Walter 1989: Haushalt - ein SPSSx-Programm zur Erfassung personaler 
* Haushalts- und Familienstrukturen, in: ZUMA Nachrichten 13(25): 7-23.
*
* Porst, Rolf 1984: Haushalte und Familien 1982: zur Erfassung und Beschreibung 
* von Haushalts- und Familienstrukturen mit Hilfe repräsentativer 
* Bevölkerungsumfragen, in: Zeitschrift für Soziologie 13(2): 165-175.
*
* Die Syntax verwendet das neue ALLBUS-Missingschema (negative fehlende Werte,
* ab ALLBUS 2016/ALLBUS-Kumulation 1980-2016)

/***
## Bitte Pfad und Dateinamen des verwendeten ALLBUS-Datensatzes und der Ausgabedatei anpassen:
***/

local data "<Pfad>\ZAxxxx_vx-x-x.dta"
local outfile "<Pfad>\ZAxxxx_famtyp.dta"



********************************************************************************

use "`data'", clear

* Bildung einer neuen Variable, die 'Eingetragene Lebenspartnerschaft' 
* mit 'Verheiratet' gleichsetzt.
recode mstat (6 = 1) (7 = 2) (8 = 3) (9 = 4), gen(famstan1)

forvalues i = 2/8 {
	gen verwand`i' = hh`i'kin
	gen famstan`i' = hh`i'mstat
}
gen anzakind = 99

* Zunaechst werden die Variablenauspraegungen der Verwandschaftsverhaeltnisse
* des Jahres 1990 recodiert analog denen von 1988; d.h. Vater/Mutter und Stief-
* vater/Stiefmutter werden zusammengelegt.
recode verwand2 verwand3 verwand4 verwand5 verwand6 verwand7 verwand8 (8 9 = 8) ///
 (10 = 9) (11 = 10) (12 = 11) (13 = 12) (14 = 13) (15 = 14) (16 = 15)

recode verwand2 verwand3 verwand4 verwand5 verwand6 verwand7 verwand8 (17 = 1) ///
 if famstan1 == 1.

recode verwand2 verwand3 verwand4 verwand5 verwand6 verwand7 verwand8 (17=2) ///
 if inrange(famstan1, 2, 5)

* Bestimmung der Haushaltsgroesse
forvalues i = 2/8 {
	gen ver`i'inhh = 0
	replace ver`i'inhh = 1 if inrange(verwand`i', 1, 15)
}
egen hhgroesse = anycount(ver*inhh), values(1)
replace hhgroesse = hhgroesse +1

* Bildung einer Variablen fuer eine Haushaltsfeinklassifikation (hhfein)
gen hhfein = 0

* Modul zur Gleichsetzung von Stiefelternverhaeltnissen mit Elternverhaeltnissen
egen vatemutt = anycount(verwand*), value(8)
egen nichtver = anycount(verwand*), value(15)

forvalues i = 2/8 {
	forvalues j = 2/8 {
		replace verwand`i' = 8 if (vatemutt == 1 & nichtver == 1 & ///
		((verwand`j' == 8 & famstan`j' == 1) & (verwand`i' == 15 & famstan`i' == 1)))
	}
}

drop vatemutt nichtver

* Aufbau einer Zaehlweise nach den Verwandschaftsbeziehungen
egen ehe = anycount(verwand*), value(1)
egen partner = anycount(verwand*), value(2)
egen eigekind = anycount(verwand*), value(3)
egen stiekind = anycount(verwand*), value(4)
egen bruschwe = anycount(verwand*), value(5)
egen stiefbru = anycount(verwand*), value(6)
egen eigenkel = anycount(verwand*), value(7)
egen vatemutt = anycount(verwand*), value(8)
egen schwieva = anycount(verwand*), value(9)
egen schwieso = anycount(verwand*), value(10)
egen schwager = anycount(verwand*), value(11)
egen grovamut = anycount(verwand*), value(12)
egen grovmpar = anycount(verwand*), value(13)
egen andverwa = anycount(verwand*), value(14)
egen nichtver = anycount(verwand*), value(15)

egen tmp_el = anymatch(vatemutt schwieva), value(1/8)
egen tmp_kind = anymatch(eigekind stiekind), v(1/8)
egen tmp_kindgen = anymatch(eigekind stiekind schwieso), v(1/8)
egen tmp_groel = anymatch(grovamut grovmpar), v(1/8)
egen tmp_bru = anymatch(bruschwe stiefbru), v(1/8)

*******************************************************************************
***                      H1 Ein-Personen-Haushalte                          ***
*******************************************************************************

*******************************************************************************
* H1A Alleinlebende Ledige
* Fall 1 von 1 = hhfein Typ 01-0
*******************************************************************************
replace hhfein = 010 if (famstan1 == 5 & verwand2 == -10)

*******************************************************************************
* H1B Alleinlebende Getrennte, Geschiedene, Verwitwete
* Fall 1 von 1 = hhfein Typ 02-0
replace hhfein = 020 if inrange(famstan1, 2, 4) & (verwand2 == -10)

*******************************************************************************
***                      H2 Ein-Generationen-Haushalte                      ***
*******************************************************************************

*******************************************************************************
* H2A Partnerpaare
* Fall 1 von 1 = hhfein Typ 03-0
*******************************************************************************

replace hhfein = 030 if ///
	(famstan1 != 1 & famstan1 != -9 & verwand2 == 2 & hhgroesse == 2)

*******************************************************************************
* H2B Ehepaare
* Fall 1 von 1 = hhfein Typ 04-0
*******************************************************************************

replace hhfein = 040 if (famstan1 == 1 & verwand2 == 1 & hhgroesse == 2)

*******************************************************************************
***                      H3 Zwei-Generationen-Haushalte                     ***
*******************************************************************************

*******************************************************************************
* H3A Ledige mit mindestens einem Kind
* Fall 1 von 2 Befragter ist lediger Elternteil = hhfein Typ 05-1
*******************************************************************************

egen tmp_h3a1 = anycount(verwand3 verwand4 verwand5 verwand6 verwand7 verwand8), ///
	v(-10, 3, 4, 10)
replace hhfein = 51 if famstan1 == 5 & inlist(verwand2, 3, 4, 10) & tmp_h3a1 == 6

*******************************************************************************
* H3A Ledige mit mindestens einem Kind                                        *
* Fall2 von 2 Befragter ist Kind eines ledigen Elternteils = hhfein Typ 05-2  *
*******************************************************************************

egen tmp_h3a2 = anycount(verwand3 verwand4 verwand5 verwand6 verwand7 verwand8), ///
	v(-10, 1, 5, 6)
replace hhfein = 52 if verwand2 == 8 & famstan2 == 5 & tmp_h3a2 == 6

*******************************************************************************
* H3B Partnerpaare mit ledigen Kindern                                        *
* Fall 1 von 4 Befragter ist Elternteil des ledigen Kindes.                   *
* Der Fall: Befragter ist Partner des Elternteils des ledigen Kindes kann nur *
* dann erfasst werden, wenn diese Person das Kind als Stiefkind bezeichnet1   *
* = hhfein Typ 06-1                                                           *
*******************************************************************************

replace hhfein = 061 if (partner == 1 & !inlist(famstan1, 1, -9) & ///
	(verwand2 == 2 | (inlist(verwand2, 3, 4) & famstan2 == 5)) & ///
	(verwand3 == 2 | (inlist(verwand3, 3, 4) & famstan3 == 5)) & ///
	(inlist(verwand4, -10, 3, 4) & inlist(famstan4, -10, 5)) & ///
	(inlist(verwand5, -10, 3, 4) & inlist(famstan5, -10, 5)) & ///
	(inlist(verwand6, -10, 3, 4) & inlist(famstan6, -10, 5)) & ///
	(inlist(verwand7, -10, 3, 4) & inlist(famstan7, -10, 5)) & ///
	(inlist(verwand8, -10, 3, 4) & inlist(famstan8, -10, 5)))

*******************************************************************************
* H3B Partnerpaare mit ledigen Kindern                                        *
* Fälle 2, 3 von 4 Befragter ist lediges Kind eines der beiden Partner        *
* A) Person 2 ist Vater/Mutter des Befragten, Person 3 ist in Kategorie 15    *
*    = hhfein Typ 06-2 = 0                                                    *
* B) Person 2 ist in Kategorie 15, Person 3 ist Vater/Mutter des Befragten    *
*    = hhfein Typ 06-3 = 0                                                    *
* Fälle 2 und 3 von 4 werden nicht berechnet, da zwar die Berechnung an sich  *
* moeglich ist, in beiden Faellen aber nicht definitv zu klaeren waere, ob die*
* mit 15 verkodete Person tatsaechlich der Partner von Vater oder Mutter ist. *
*******************************************************************************

*******************************************************************************
* H3B Partnerpaare mit ledigen Kindern                                        *
* Fall 4 von 4 Befragter ist lediges Kind beider Partner                      *
* = hhfein Typ 06-4                                                           *
*******************************************************************************

replace hhfein = 064 if famstan1 == 5 & ///
	verwand2 == 8 & !inlist(famstan2, 1, -9) & ///
	verwand3 == 8 & !inlist(famstan3, 1, -9) & ///
	inlist(verwand4, -10, 5, 6) & inlist(famstan4, -10, 5) & ///
	inlist(verwand5, -10, 5, 6) & inlist(famstan5, -10, 5) & ///
	inlist(verwand6, -10, 5, 6) & inlist(famstan6, -10, 5) & ///
	inlist(verwand7, -10, 5, 6) & inlist(famstan7, -10, 5) & ///
	inlist(verwand8, -10, 5, 6) & inlist(famstan8, -10, 5)

*******************************************************************************
* H3C Partnerpaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere Kinder
* Fall 1 von 7: Befragter ist einer der Partner 
* = hhfein Type 07-1
*******************************************************************************

egen tmp_h3c1a = anycount(verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 3, 4, 10)
egen tmp_h3c1b = anymatch(famstan3 famstan4 famstan5 famstan6 famstan7 ///
	famstan8), values(1/4)
replace hhfein = 071 if !inlist(famstan1, 1, -9) & verwand2 == 2 & ///
	inlist(verwand3, 3, 4, 10) & tmp_h3c1a == 5 & tmp_h3c1b == 1

*******************************************************************************
* H3C Partnerpaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weiter nicht-ledige Kinder
* Fall 2 von 7: Befragter ist nicht-lediges Kind
* A) ...beider Partner 
* = hhfein Typ 07-2
*******************************************************************************

gen tmp_h3c2 = 1
forvalues i = 4/8 {
	replace tmp_h3c2 = 0 if ///
		!(inlist(verwand`i', -10, 5, 6) | (verwand`i' == 1 & famstan`i' == 1))
}

replace hhfein = 072 if vatemutt == 2 & famstan1 != 5 & ///
	((verwand2==8 & !inlist(famstan2,1,-9))|(verwand2==1 & famstan2==1)) & ///
	((verwand3==8 & !inlist(famstan3,1,-9))|(verwand2==1 & famstan2==1)) & ///
	tmp_h3c2 == 1

*******************************************************************************
* H3C Partnerpaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Fall 3 von 7: Befragter ist nicht lediges Kind
* B) ...des aelteren Partners = hhfein Typ 07-3 = 0
* C) ...des juengeren Partners = hhfein Typ 07-4 = 0
* Fall 3 und 4 von 7 werden nicht berechnet. Zwar ist die Berechnung an sich
* prinzipiell möglich, in beiden Faellen waere aber nicht definitiv zu 
* klaeren, ob die mit 15 verkodete Person tatsaechlich der Partner von 
* Vater oder Mutter ist.
*******************************************************************************

*******************************************************************************
* H3C Partnerpaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Fall 5 von 7: Befragter ist lediges Kind
* A) ...beider Partner
* = hhfein Typ 07-5
*******************************************************************************

egen tmp_h3c5a = anycount(verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 5, 6, 11)
egen tmp_h3c5b = anymatch(famstan4 famstan5 famstan6 famstan7 famstan8), ///
	values(1/4)
	
replace hhfein = 075 if famstan1 == 5 & ///
	verwand2 == 8 & !inlist(famstan2, 1, -9) & ///
	verwand3 == 8 & !inlist(famstan3, 1, -9) & ///
	tmp_h3c5a == 5 & tmp_h3c5b == 1
drop tmp_h3c*

*******************************************************************************
* H3C Partnerpaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Fall 6 von 7: Befragter ist lediges Kind
* B) ... des aelteren Partners = hhfein Typ 07-6 = 0
* C) ... des juengeren Partners = hhfein Typ 07-7 = 0
* Faelle 6 und 7 von 7 werden ebenfalls nicht berechnet. Auch in diesen 
* Faellen ist die berechnung prinzipiell moeglich, aber auch hier waere 
* nicht definitiv zu klaeren, ob die mit 15 verkodete Person tatsaechlich 
* der Partner on Vater oder Mutter ist.
*******************************************************************************

*******************************************************************************
* H3D Partnerpaare mit Enkeln
* Fall 1 von 5: Befragter ist Grosselternteil des Enkels = hhfein Typ 08-1
*******************************************************************************

egen tmp_h3d1 = anycount(verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 7)
replace hhfein = 081 if !inlist(famstan1, 1, -9) & ///
	verwand2 == 2 & verwand3 == 7 & tmp_h3d1 == 5

*******************************************************************************
* H3D Partnerpaare mit Enkeln
* Fall 2 von 5: Befragter ist Partner des Grosselternteils
* Dieser HH-Typ ist nicht eindeutig identifizierbar, da es den Code "Enkel 
* meines Partners" nicht gibt. Richtigerweise muesste deshalb vercodet werden:
* - die zweite Person als 2
* - die dritte und ggfs. weitere Personen als 15
* Dieser Typ waere nicht zu unterscheiden von H9 (Wohngemeinschaften);
* sollte tatsaechlich eine solche HH-Konstellation auftreten, waere diese in
* dieser Typologie eine Wohngemeinschaft!
* = hhfein Typ 08-2 = 0
*******************************************************************************

*******************************************************************************
* H3D Partnerpaare mit Enkeln
* Fall 3 von 5: Befragter ist Enkel beider Partner = hhfein Typ 08-3
*******************************************************************************

egen tmp_h3d3 = anycount(verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 1, 5, 6)
replace hhfein = 083 if verwand2 == 12 & !inlist(famstan1, 1, -9) & ///
	verwand3 == 12 & !inlist(famstan3, 1, -9) & tmp_h3d3 == 5
drop tmp_h3d*

*******************************************************************************
* H3D Partnerpaare mit Enkeln
* Fall 4 von 5: Befragter ist Enkel einer der Partner
* Dieser HH-Typ ist nicht eindeutig identifizierbar, da es den Code "Partner
* meines Grosselternteils" nicht gibt. Richtigerweise muesste deshalb vercodet
* werden: 
* - die zweite Person als 12 und die dritte als 15 oder
* - die dritte Person als 12 und die zweite als 15
* Dieser Typ waere nicht zu unterscheiden von H8 (Wohngemeinschaft mit
* Familienkern); sollte tatsaechlich eine solche HH-Konstellation auftreten,
* waere sie unter H8 zu finden. = hhfein Typ 08-4 = 0
*******************************************************************************

*******************************************************************************
* H3D Partnerpaare mit Enkeln
* Fall 5 von 5: Befragter ist Enkel des anderen Partners
* Auch dieser HH-Typ ist nicht eindeutig rekonstruierbar. Er etnspricht H3D,
* Fall 4, sodass hier das Gleiche gilt wie dort. = hhfein Typ 08-5 = 0
*******************************************************************************

*******************************************************************************
* H3E Ehepaare mit ausschliesslich ledigen Kindern
* entspricht F1 - Kernfamilie
* Fall 1 von 4: Vollstaendige Kernfamilie, Befragter ist Elternteil
* = hhfein Typ 09-1
*******************************************************************************

gen tmp_h3e1 = 1
forvalues i = 4/8 {
	replace tmp_h3e1 = 0 if !((verwand`i' == 1 & famstan`i' == 1) | ///
		(inlist(verwand`i', -10, 3, 4) & inlist(famstan`i', -10, 5)))
}

replace hhfein = 091 if ehe == 1 & famstan1 == 1 & ///
	((verwand2 == 1 & famstan2 == 1) | ///
		(inlist(verwand2, 3, 4) & famstan2 == 5)) & ///
	((verwand3 == 1 & famstan3 == 1) | ///
		(inlist(verwand3, 3, 4) & famstan3 == 5)) & ///
	tmp_h3e1 == 1

*******************************************************************************
* H3E Ehepaare mit ausschliesslich ledigen Kindern 
* entspricht F1 - Kernfamilie
* Fall 2 von 4: Vollstaendige Kernfamilie, Befragter ist Kind 
* = hhfein Typ 09-2
*******************************************************************************

replace hhfein = 092 if vatemutt == 2 & famstan1 == 5 & ///
	((inlist(verwand2, 5, 6) & famstan2 == 5) | ///
		(verwand2 == 8 & famstan2 == 1)) & ///
	((inlist(verwand3, 5, 6) & famstan3 == 5) | ///
		(verwand3 == 8 & famstan3 == 1)) & ///
	((inlist(verwand4, -10, 5, 6) & inlist(famstan4, -10, 5)) | ///
		(verwand4 == 8 & famstan4 == 1)) & ///
	((inlist(verwand5, -10, 5, 6) & inlist(famstan5, -10, 5)) | ///
		(verwand5 == 8 & famstan5 == 1)) & ///
	inlist(verwand6, -10, 5, 6) & inlist(famstan6, -10, 5) & ///
	inlist(verwand7, -10, 5, 6) & inlist(famstan7, -10, 5) & ///
	inlist(verwand8, -10, 5, 6) & inlist(famstan8, -10, 5)

*******************************************************************************
* H3E Ehepaare mit ausschließlich ledigen Kindern
* entspricht F1 - Kernfamilie
* Fall 3 von 4: Unvollstaendige Kernfamilie, Befragter ist Elternteil
* = hhfein Typ 09-3
*******************************************************************************

egen tmp_h3e3a = anycount(verwand3 verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 3, 4)
egen tmp_h3e3b = anycount(famstan3 famstan4 famstan5 famstan6 famstan7 famstan8), ///
	values(-10, 5)

replace hhfein = 093 if inrange(famstan1, 2, 4) & ///
	inlist(verwand2, 3, 4) & famstan2 == 5 & tmp_h3e3a == 6 & tmp_h3e3b == 6

*******************************************************************************
* H3E Ehepaare mit ausschliesslich ledigen Kindern
* entspricht F1 - Kernfamilie
* Fall 4 von 4: Unvollstandige Kernfamilie, Befragter ist Kind
* = hhfein Typ 09-4
*******************************************************************************

egen tmp_h3e4a = anycount(verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 5, 6)
egen tmp_h3e4b = anycount(famstan4 famstan5 famstan6 famstan7 famstan8), ///
	values(-10, 5)
replace hhfein = 094 if vatemutt == 1 & famstan1 == 5 & ///
	((inlist(verwand2, 5, 6) & famstan2 == 5) | ///
		(verwand2 == 8 & inrange(famstan2, 2, 4))) & ///
	((inlist(verwand3, -10, 5, 6) & inlist(famstan3, -10, 5)) | ///
		(verwand3 == 8 & inrange(famstan3, 2, 4))) & ///
	tmp_h3e4a == 5 & tmp_h3e4b == 5
drop tmp_h3e*

*******************************************************************************
* H3F Ehepaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Entspricht F2 - Zwei-Generationen-Familie (teilweise)
* Fall 1 von 8: Vollstaendige Zwei-Generationen-Familie,
* Befragter ist Elternteil = hhfein Typ 10-1
*******************************************************************************

egen tmp_h3f1a = anycount(verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 3, 4, 10)
egen tmp_h3f1b = anymatch(famstan3 famstan4 famstan5 famstan6 famstan7 famstan8), ///
	values(1/4)
replace hhfein = 101 if famstan1 == 1 & verwand2 == 1 & ///
	inlist(verwand3, 3, 4, 10) & tmp_h3f1a == 5 & tmp_h3f1b == 1

*******************************************************************************
* H3F Ehepaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Entspricht F2 - Zwei-Generationen-Familie (teilweise)
* Fall 2 von 8: Unvollstaendige Zwei-Generationen-Familie,
* Befragter ist Elternteil = hhfein Typ 10-2
*******************************************************************************

egen tmp_h3f2a = anycount(verwand3 verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 3, 4, 10)
egen tmp_h3f2b = anymatch(famstan2 famstan3 famstan4 famstan5 famstan6 ///
	famstan7 famstan8), values(1/4)
replace hhfein = 102 if inrange(famstan1, 2, 4) & inlist(verwand2,3,4,10) & ///
	tmp_h3f2a == 6 & tmp_h3f2b == 1

*******************************************************************************
* H3F Ehepaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Entspricht F2 - Zwei-Generationen-Familie (teilweise)
* Fall 3 von 8: Vollstaendige Zwei-Generationen-Familie,
* Befragter ist lediges Kind = hhfein Typ 10-3
*******************************************************************************

egen tmp_h3f3a = anycount(verwand5 verwand6 verwand7 verwand8), v(-10, 5, 6, 11)
egen tmp_h3f3b = anymatch(famstan4 famstan5 famstan6 famstan7 famstan8), v(1/4)
replace hhfein = 103 if famstan1 == 5 & ///
	verwand2 == 8 & famstan2 == 1 & ///
	verwand3 == 8 & famstan3 == 1 & ///
	inlist(verwand4, 5, 6, 11) & tmp_h3f3a == 4 & tmp_h3f3b == 1

*******************************************************************************
* H3F Ehepaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Entspricht F2 - Zwei-Generationen-Familie (teilweise)
* Fall 4 von 8: Unvollstaendige Zwei-Generationen-Familie,
* Befragter ist lediges Kind = hhfein Typ 10-4
*******************************************************************************

egen tmp_h3f4a = anycount(verwand4 verwand5 verwand6 verwand7 ///
	verwand8), values(-10, 5, 6, 11)
egen tmp_h3f4b = anymatch(famstan3 famstan4 famstan5 famstan6 famstan7 ///
	famstan8), values(1/4)
replace hhfein = 104 if famstan1 == 5 & verwand2 == 8 & ///
	inlist(verwand3, 5, 6, 11) & tmp_h3f4a == 5 & tmp_h3f4b == 1

*******************************************************************************
* H3F Ehepaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Entspricht F2 - Zwei-Generationen-Familie (teilweise)
* Fall 5 von 8: Zwei-Generationen-Familie mit zwei kompletten
* Elterngenerationen, Befragter ist nicht-lediges Kind = hhfein Typ 10-5
*******************************************************************************

egen tmp_h3f5 = anycount(verwand2 verwand3 verwand4 verwand5), v(8, 9)
replace hhfein = 105 if inrange(famstan1, 1, 4) & tmp_h3f5 == 4 & ///
	((verwand6 == 1 & famstan6 == 1) | inlist(verwand6, -10, 5, 6, 11)) & ///
	((verwand7 == 1 & famstan6 == 1) | inlist(verwand7, -10, 5, 6, 11)) & ///
	((verwand8 == 1 & famstan6 == 1) | inlist(verwand8, -10, 5, 6, 11))

*******************************************************************************
* H3F Ehepaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Entspricht F2 - Zwei-Generationen-Familie (teilweise)
* Fall 6 von 8: Zwei-Generationen-Familie mit anderthalb Elterngenerationen,
* Befragter ist nicht-lediges Kind = hhfein Typ 10-6
*******************************************************************************

gen tmp_h3f6 = 1
forvalues i = 5/8 {
	replace tmp_h3f6 = 0 if !((verwand`i' == 1 & famstan`i' == 1) | ///
		inlist(verwand`i', -10, 5, 6, 11))
}
replace hhfein = 106 if inlist(famstan1, 1/4) & tmp_h3f6 == 1 & ///
	inlist(verwand2, 8, 9) & inlist(verwand3, 8, 9) & inlist(verwand4, 8, 9)

*******************************************************************************
* H3F Ehepaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Entspricht F2 - Zwei-Generationen-Familie (teilweise)
* Fall 7 von 8: Zwei-Generationen-Familien mit zwei Personen der 
* Elterngeneration, Befragter ist nicht-lediges Kind oder dessen Ehepartner
* = hhfein Typ 10-7
*******************************************************************************

gen tmp_h3f7 = 1
forvalues i = 4/8 {
    replace tmp_h3f7 = 0 if !((verwand`i' == 1 & famstan`i' == 1) | ///
		inlist(verwand`i', -10, 5, 6, 11))
}
replace hhfein = 107 if inrange(famstan1, 1, 4) & ///
	inlist(verwand2, 8, 9) & inlist(verwand3, 8, 9) & tmp_h3f7 == 1

*******************************************************************************
* H3F Ehepaare mit mindestens einem nicht-ledigen Kind;
* ggfs. weitere ledige Kinder
* Entspricht F2 - Zwei-Generationen-Familie (teilweise)
* Fall 8 von 8: Zwei-Generationen-Familien mit einem Elter-/Schiegereltern-
* teil, Befragter ist nicht-lediges Kind oder dessen Ehepartner 
* = hhfein Typ 10-8
*******************************************************************************

gen tmp_h3f8 = 1
forvalues i = 3/8 {
    replace tmp_h3f8 = 0 if !((verwand`i' == 1 & famstan`i' == 1) | ///
		inlist(verwand`i', -10, 5, 6, 11))
}
replace hhfein = 108 if ///
	inrange(famstan1, 1, 4) & (inlist(verwand2, 8, 9) & tmp_h3f8 == 1) | ///
	(hhfein == 0 & inrange(famstan1, 1, 4) & (vatemutt == 1 | schwieva == 1) & tmp_kindgen == 0 & ///
	tmp_groel == 0 & andverwa == 0 & nichtver == 0 & partner == 0 & eigenkel == 0)
drop tmp_h3f*

*******************************************************************************
* H3G Ehepaare mit Enkeln
* Entspricht F2 - Zwei-Generationen-Familien (teil-weise)
* Fall 1 von 6: Aeltere Generation vollstaendig, Befragter ist Grosselternteil
* = hhfein Typ 11-1
*******************************************************************************

egen tmp_h3g1 = anycount(verwand4 verwand5 verwand6 verwand7 verwand8), v(-10, 7)
replace hhfein = 111 if verwand2 == 1 & famstan2 == 1 & verwand3 == 7 & ///
	tmp_h3g1 == 5

*******************************************************************************
* H3G Ehepaare mit Enkeln
* Entspricht F2 - Zwei-Generationen-Familien (teil-weise)
* Fall 2 von 6: Aeltere Generation unvollstaendig, Befragter ist 
* Grosselternteil = hhfein Typ 11-2
*******************************************************************************

egen tmp_h3g2 = anycount(verwand3 verwand4 verwand5 verwand6 verwand7 verwand8), ///
	values(-10, 7)
replace hhfein = 112 if verwand2 == 7 & tmp_h3g2 == 6

*******************************************************************************
* H3G Ehepaare mit Enkeln
* Entspricht F2 - Zwei-Generationen-Familien (teil-weise)
* Fall 3 von 6: Ver Personen der aelteren Generation, Befragter ist Enkel
* = hhfein Typ 11-3
*******************************************************************************

egen tmp_h3g3a = anycount(verwand2 verwand3 verwand4 verwand5), v(12, 13)
egen tmp_h3g3b = anycount(verwand6 verwand7 verwand8), v(-10, 1, 2, 5, 6)
replace hhfein = 113 if tmp_h3g3a == 4 & tmp_h3g3b == 3

*******************************************************************************
* H3G Ehepaare mit Enkeln
* Entspricht F2 - Zwei-Generationen-Familien (teil-weise)
* Fall 4 von 6: Drei Personen der aelteren Generation, Befragter ist Enkel
* = hhfein Typ 11-4
*******************************************************************************

egen tmp_h3g4a = anycount(verwand2 verwand3 verwand4), v(12, 13)
egen tmp_h3g4b = anycount(verwand5 verwand6 verwand7 verwand8), v(-10, 1, 2, 5, 6)
replace hhfein = 114 if tmp_h3g4a == 3 & tmp_h3g4b == 4

*******************************************************************************
* H3G Ehepaare mit Enkeln
* Entspricht F2 - Zwei-Generationen-Familien (teil-weise)
* Fall 5 von 6: Zwei Personen der aelteren Generation, Befragter ist Enkel
* = hhfein Typ 11-5
*******************************************************************************

egen tmp_h3g5 = anycount(verwand4 verwand5 verwand6 verwand7 verwand8), ///
	v(-10, 1, 2, 5, 6)
replace hhfein = 115 if inlist(verwand2, 12, 13) & inlist(verwand3, 12, 13) & ///
	tmp_h3g5 == 5

*******************************************************************************
* H3G Ehepaare mit Enkeln
* Entspricht F2 - Zwei-Generationen-Familien (teil-weise)
* Fall 6 von 6: Eine Person der aelteren Generation, Befragter ist Enkel
* = hhfein Typ 11-6
*******************************************************************************

egen tmp_h3g6 = anycount(verwand3 verwand4 verwand5 verwand6 verwand7 verwand8), ///
	v(-10, 1, 2, 5, 6)
replace hhfein = 116 if inlist(verwand2, 12, 13) & tmp_h3g6 == 6
drop tmp_h3g*

*******************************************************************************
* H4 Drei-Generationen-Haushalte
* Angehoerige dreier linear aufeinanderfolgenden Generationen, wobei 
* mindestens eine Person einer jeden Generation unabhaengig vom 
* Familienstand tatsaechlich im Haushalt leben muss
* Entspricht F3 - Drei-Generationen-Familie
* Fall 1 von 3: Befragter ist Grosselternteil, d.h. mit ihm im HH muessen 
* mindestens ein Kind oder Schwiegerkind und mindestens ein Enkel leben
* = hhfein Typ 12-1
*******************************************************************************

replace hhfein = 121 if hhfein == 0 & tmp_kindgen == 1 & eigenkel >= 1 & ///
	partner == 0 & tmp_el == 0 & tmp_groel == 0 & andverwa == 0 & nichtver == 0

*******************************************************************************
* H4 Drei-Generationen-Haushalte
* Angehoerige dreier linear aufeinanderfolgenden Generationen, wobei 
* mindestens eine Person einer jeden Generation unabhaengig vom 
* Familienstand tatsaechlich im Haushalt leben muss
* Entspricht F3 - Drei-Generationen-Familie
* Fall 2 von 3: Befragter ist Elternteil, d.h. mit ihm im HH moessen 
* mindestens ein Eltern- oder Schiegerelternteil und mindestens ein Kind leben
* = hhfein Typ 12-2
*******************************************************************************

replace hhfein = 122 if hhfein == 0 & tmp_el == 1 & tmp_kindgen == 1 & ///
	eigenkel == 0 & tmp_groel == 0 & andverwa == 0 & nichtver == 0 & partner == 0

*******************************************************************************
* H4 Drei-Generationen-Haushalte
* Angehoerige dreier linear aufeinanderfolgenden Generationen, wobei 
* mindestens eine Person einer jeden Generation unabhaengig vom 
* Familienstand tatsaechlich im Haushalt leben muss
* Entspricht F3 - Drei-Generationen-Familie
* Fall 3 von 3: Befragter ist Kind, d.h. mit ihm im HH muessen mindestens 
* ein Grosselternteil und mindestens ein Eltern- oder Schwiegerelternteil 
* leben = hhfein Typ 12-3
*******************************************************************************

replace hhfein = 123 if hhfein == 0 & tmp_groel == 1 & tmp_el == 1 & ///
	partner == 0 & tmp_kindgen == 0 & eigenkel == 0 & andverwa == 0 & nichtver == 0

*******************************************************************************
* H5 Vier-Generationen-Haushalte
* Angehoerige vierer aufeinanderfolgender Generationen, wobei mindestens aus 
* drei Generationen je eine Person tatsaechlich im HH leben muss und 
* zugleich mindestens eine Person der ersten und mindestens eine Person der 
* letzten Generation
* Entspricht F4 - Vier-Generationen-Familie
* Fall 1 von 4: Befragter ist Grosselternteil, d.h. mit ihm muss mindestens 
* ein Urenkel leben. Dieser ist aber als solcher nicht identifizierbar!!
* = hhfein Typ 13-1 = 0
*******************************************************************************

*******************************************************************************
* H5 Vier-Generationen-Haushalte
* Angehoerige vierer aufeinanderfolgender Generationen, wobei mindestens aus 
* drei Generationen je eine Person tatsaechlich im HH leben muss und 
* zugleich mindestens eine Person der ersten und mindestens eine Person der 
* letzten Generation
* Entspricht F4 - Vier-Generationen-Familie
* Fall 2 von 4: Befragter ist Elternteil, d.h. mit ihm im HH muss mindestens 
* ein Elternteil und ein Enkel leben = hhfein Typ 13-2
*******************************************************************************

replace hhfein = 132 if hhfein == 0 & tmp_el == 1 & eigenkel >= 1 & ///
	tmp_groel == 0 & partner == 0 & andverwa == 0 & nichtver == 0 

*******************************************************************************
* H5 Vier-Generationen-Haushalte
* Angehoerige vierer aufeinanderfolgender Generationen, wobei mindestens aus 
* drei Generationen je eine Person tatsaechlich im HH leben muss und 
* zugleich mindestens eine Person der ersten und mindestens eine Person der 
* letzten Generation
* Entspricht F4 - Vier-Generationen-Familie
* Fall 3 von 4: Befragter ist Kind, d.h. mit ihm im HH muessen mindestens 
* ein Grosselternteil und ein Kind leben = hhfein Typ 13-3
*******************************************************************************

replace hhfein = 133 if hhfein == 0 & tmp_groel == 1 & tmp_kindgen == 1 & ///
	eigenkel == 0 & andverwa == 0 & nichtver == 0 & partner == 0

******************************************************************************
* H5 Vier-Generationen-Haushalte
* Angehoerige vierer aufeinanderfolgender Generationen, wobei mindestens aus 
* drei Generationen je eine Person tatsaechlich im HH leben muss und 
* zugleich mindestens eine Person der ersten und mindestens eine Person der 
* letzten Generation
* Entspricht F4 - Vier-Generationen-Familie
* Fall 4 von 4: Befragter ist Enkel, d.h. mit ihm im HH muss mindestens ein 
* Urgrosselternteil leben. Dieser ist nicht identifizierbar!!
* = hhfein Typ 13-4 = 0
*******************************************************************************

*******************************************************************************
* H6 Verwandtschaftshaushalte mit Familienkern
* Alle HH's der Typen H2B und H3E bis H5 mit zusaetzlich mindestens einer 
* den Haushaltsmitgliedern verwandten Person ausserhalb der linearen 
* Generationenfolge
* Entspricht F5 - Erweiterte Familien
* = hhfein Typ 14-0
*******************************************************************************
gen tmp_h6 = 0
replace tmp_h6 = 1 if hhfein == 0 & ((famstan1 <= 4 & tmp_bru == 1) | schwager >= 1 | andverwa >= 1)

*Fall 1
replace hhfein = 140 if tmp_h6 == 1 & ehe == 1 & tmp_kindgen == 0 & tmp_el == 0 & ///
	eigenkel == 0 & tmp_groel == 0 & nichtver == 0 & partner == 0

*Fall 2
replace hhfein = 140 if tmp_h6 == 1 & tmp_bru == 1 & schwager >= 1 & ehe == 0 & ///
	partner == 0 & tmp_kindgen == 0 & eigenkel == 0 & tmp_el == 0 & tmp_groel == 0 & nichtver == 0

*Fall 3
replace hhfein = 140 if tmp_h6 == 1 & ehe == 1 & tmp_kindgen == 1 & ///
	eigenkel == 0 & tmp_el == 0 & tmp_groel == 0 & nichtver == 0 & partner == 0

*Fall 4
gen tmp_verh_el = 0
forvalues i = 2/8 {
    replace tmp_verh_el = 1 if (verwand`i' == 8 & famstan`i' == 1)
}
replace hhfein = 140 if tmp_h6 == 1 & famstan1 == 5 & vatemutt == 2 & tmp_verh_el == 1 & ///
	partner == 0 & tmp_kindgen == 0 & tmp_groel == 0 & schwieva == 0 & nichtver == 0 & ehe == 0

*Fall 5
replace hhfein = 140 if tmp_h6 == 1 & inrange(famstan1, 2, 4) & tmp_kindgen == 1 & ///
	partner == 0 & eigenkel == 0 & tmp_el == 0 & tmp_groel == 0 & nichtver == 0 & ehe == 0

*Fall 6
gen tmp_getr_el = 0
forvalues i = 2/8 {
	replace tmp_getr_el = 1 if verwand`i' == 8 & inrange(famstan`i', 2, 4)
}
replace hhfein = 140 if tmp_h6 == 1 & famstan1 == 5 & vatemutt == 1 & tmp_getr_el == 1 & ///
	partner == 0 & tmp_kindgen == 0 & eigenkel == 0 & schwieva == 0 & tmp_groel == 0 & ///
	nichtver == 0 & ehe == 0
	
*Fall 7
replace hhfein = 140 if tmp_h6 == 1 & famstan1 != 5 & tmp_el == 1 & tmp_kindgen == 0 & ///
	eigenkel == 0 & tmp_groel == 0 & nichtver == 0 & partner == 0
	
*Fall 8
replace hhfein = 140 if tmp_h6 == 1 & ehe == 1 & eigenkel >= 1 & tmp_kindgen == 0 & tmp_el == 0 & ///
	tmp_groel == 0 & nichtver == 0 & partner == 0
	
*Fall 9
replace hhfein = 140 if tmp_h6 == 1 & eigenkel >= 1 & ehe == 0 & partner == 0 & ///
	tmp_kindgen == 0 & tmp_el == 0 & tmp_groel == 0 & nichtver == 0

*Fall 10
replace hhfein = 140 if tmp_h6 == 1 & tmp_groel == 1 & tmp_kindgen == 0 & eigenkel == 0 & ///
	tmp_el == 0 & nichtver == 0
	
*Fall 11
replace hhfein = 140 if tmp_h6 == 1 & tmp_kindgen == 1 & eigenkel >= 1 & tmp_el == 0 & ///
	tmp_groel == 0 & nichtver == 0
	
*Fall 12
replace hhfein = 140 if tmp_h6 == 1 & tmp_el == 1 & tmp_kindgen == 1 & eigenkel == 0 & ///
	tmp_groel == 0 & nichtver == 0

*Fall 13
replace hhfein = 140 if tmp_h6 == 1 & tmp_groel == 1 & tmp_el == 1 & ///
	tmp_kindgen == 0 & eigenkel == 0 & nichtver == 0

*Fall 14
replace hhfein = 140 if tmp_h6 == 1 & tmp_el == 1 & eigenkel >= 1 & tmp_groel == 0 & nichtver == 0

*Fall 15
replace hhfein = 140 if tmp_h6 == 1 & tmp_groel == 1 & tmp_kindgen == 1 & eigenkel == 0 & nichtver == 0

	
*******************************************************************************
* H7 Verwandtschaftshaushalte ohne Familienkern
* Hier H7A: Haushalte der Typen 2A, 3A - 3D mit mindestens einem zusätzlichen
* Verwandten außerhalb der linearen Generationenfolge
********************************************************************************
egen tmp_h7a = anymatch(bruschwe stiefbru andverwa), v(1/8)
gen tmp_h7 = tmp_h7a == 1 & hhfein == 0

*Fall 1:
replace hhfein = 150 if tmp_h7 == 1 & partner == 1 & ehe == 0 & tmp_kind == 0 & ///
	eigenkel == 0 & tmp_el == 0 & tmp_groel == 0 & nichtver == 0

*Fall 2:
replace hhfein = 150 if tmp_h7 == 1 & famstan1 == 5 & tmp_kind == 1 & ///
	ehe == 0 & partner == 0 & tmp_el == 0 & tmp_groel == 0 & nichtver == 0 & eigenkel == 0

*Fall 3:
gen tmp_led_el = 0 
forvalues i = 2/8 {
	replace tmp_led_el = 1 if verwand`i' == 8 & famstan`i' == 5
}
replace hhfein = 150 if tmp_h7 == 1 & vatemutt == 1 & tmp_led_el == 1 & ///
	partner == 0 & tmp_kind == 0 & eigenkel == 0 & schwieva == 0 & tmp_groel == 0 & nichtver == 0
	
*Fall 4:
replace hhfein = 150 if tmp_h7 == 1 & partner == 1 & ehe == 0 & tmp_kind == 1 & ///
	eigenkel == 0 & tmp_el == 0 & tmp_groel == 0 & nichtver == 0

*Fall 5:
gen tmp_el_unver = 0
forvalues i = 2/8 {
	replace tmp_el_unver = 1 if verwand`i' == 8 & famstan`i' != 1 & famstan`i' != -9
}
replace hhfein = 150 if tmp_h7 == 1 & vatemutt == 2 & tmp_el_unver == 1 & partner == 0 & ///
	tmp_kindgen == 0 & eigenkel == 0 & tmp_groel == 0 & schwieva == 0 & nichtver == 0
	
*Fall 6:
replace hhfein = 150 if tmp_h7 == 1 & partner == 1 & eigenkel >= 1 & ehe == 0 & tmp_kindgen == 0 & ///
	tmp_el == 0 & tmp_groel == 0 & nichtver == 0

*Fall 7:
gen tmp_schwager_nichtver = 0
forvalues i = 2/8 {
	replace tmp_schwager_nichtver = 1 if verwand`i' == 12 & famstan`i' != 1 & famstan`i' != -9
}
replace hhfein = 150 if tmp_h7 == 1 & grovamut == 2 & tmp_schwager_nichtver == 1 & ///
	partner == 0 & tmp_kindgen == 0 & eigenkel == 0 & tmp_el == 0 & grovmpar == 0 & nichtver == 0

********************************************************************************
* H7 Verwandtschaftshaushalte ohne Familienkern
* Hier H7B: Verwandte in nicht linearer Generationenfolge plus zusaetzliche
* nicht-verwandte Personen
* = hhfein Typ 16-0
*********************************************************************************

replace hhfein = 160 if tmp_h7 == 1 & ehe == 0 & tmp_kindgen == 0 & eigenkel == 0 & ///
	tmp_el == 0 & tmp_groel == 0 & schwager == 0 & partner == 0 & nichtver >= 1

********************************************************************************
* H7 Verwandtschaftshaushalte ohne Familienkern
* Hier H7C: Nur Verwandte in nicht-linearer Generationenfolge
* = hhfein Typ 17-0
********************************************************************************

egen tmp_h7c = anymatch(bruschwe stiefbru andverwa schwager schwieso schwieva), v(1/8)
replace hhfein = 170 if hhfein == 0 & tmp_h7c & tmp_kind == 0 & eigenkel == 0 & tmp_groel == 0 & ///
	vatemutt == 0 & nichtver == 0 & ehe == 0 & partner == 0
drop tmp_h7*

********************************************************************************
* H8 Wohngemeinschaften mit Familienkern
* Haushalte der Typen H2B und H3E bis H6 mit mindestens einer den Haushalts-
* mitgliedern nicht verwandten Person
* 
* Entspricht F6 - Haushaltsfamilien
* = hhfein Typ 18-0
*********************************************************************************

*Partner oder nichtverwandte Person im Haushalt?
gen tmp_h8 = 0
replace tmp_h8 = 1 if (nichtver >= 1 | partner == 1) & hhfein == 0

*Fall 1
replace hhfein = 180 if tmp_h8 == 1 & ehe == 1 & ///
	tmp_kindgen == 0 & eigenkel == 0 & tmp_el == 0 & tmp_groel == 0

*Fall 2
replace hhfein = 180 if tmp_h8 == 1 & ehe == 1 & tmp_kindgen == 1 & ///
	eigenkel == 0 & tmp_el == 0 & tmp_groel == 0

*Fall 3
gen tmp3 = 0
forvalues i = 2/8 {
	replace tmp3 = 1 if (verwand`i' == 8 & famstan`i' == 1)
}
replace hhfein = 180 if tmp_h8 == 1 & famstan1 == 5 & vatemutt == 2 & tmp3 == 1 & ///
	tmp_kindgen == 0 & eigenkel == 0 & schwieva == 0 & tmp_groel == 0 & ehe == 0

*Fall 4
replace hhfein = 180 if tmp_h8 == 1 & inrange(famstan1, 2, 4) & ///
	tmp_kindgen == 1 & eigenkel == 0 & tmp_el == 0 & tmp_groel == 0 & ehe == 0

*Fall 5
gen tmp5 = 0
forvalues i = 2/8 {
	replace tmp5 = 1 if (verwand`i' == 8 & inrange(famstan`i', 2, 4))
}
replace hhfein = 180 if tmp_h8 == 1 & famstan1 == 5 & vatemutt == 1 & ///
	tmp5 == 1 & tmp_kindgen == 0 & eigenkel == 0 & schwieva == 0 & tmp_groel == 0 & ehe == 0

*Fall 6
replace hhfein = 180 if tmp_h8 == 1 & famstan1 != 5 & tmp_el == 1 & ///
	tmp_kindgen == 0 & tmp_groel == 0 & eigenkel == 0

*Fall 7
replace hhfein = 180 if tmp_h8 == 1 & ehe == 1 & eigenkel >= 1 & ///
	tmp_kindgen == 0 & tmp_el == 0 & tmp_groel == 0

*Fall 8
replace hhfein = 180 if tmp_h8 == 1 & ehe == 0 & eigenkel >= 1 & ///
	tmp_kindgen == 0 & tmp_el == 0 & tmp_groel == 0

*Fall 9
replace hhfein = 180 if tmp_h8 == 1 & tmp_groel == 1 & ///
	tmp_kindgen == 0 & tmp_el == 0 & eigenkel == 0

*Fall 10
replace hhfein = 180 if tmp_h8 == 1 & tmp_kindgen == 1 & eigenkel >= 1 & ///
	tmp_el == 0 & tmp_groel == 0
	
*Fall 11
replace hhfein = 180 if tmp_h8 == 1 & tmp_el == 1 & tmp_kindgen == 1 & ///
	eigenkel == 0 & tmp_groel == 0

*Fall 12
egen tmp12 = anycount(eigekind stiekind eigenkel schwieso), v(1/8)
replace hhfein = 180 if tmp_h8 == 1 & tmp_groel == 1 & tmp_el == 1 & ///
	tmp_kindgen == 0 & eigenkel == 0
	
*Fall 13
replace hhfein = 180 if tmp_h8 == 1 & tmp_el == 1 & eigenkel >= 1 & ///
	tmp_groel == 0
	
*Fall 14
replace hhfein = 180 if tmp_h8 == 1 & tmp_groel == 1 & tmp_kindgen == 1 & eigenkel == 0

*********************************************************************************
* H9 Wohngemeinschaften
* Haushalte ausschließlich nicht miteinander verwandter Personen, sofern sie
* nicht ausschließlich aus einem Partnerpaar und dessen Kindern bestehen
* (also ausschließlich H2A und H3B bis H3D)
* = hhfein Typ 19-0
**********************************************************************************

replace hhfein = 190 if (hhfein == 0 & nichtver >= 1 & ehe == 0 & tmp_bru == 0 & tmp_el == 0 & ///
	tmp_groel == 0 & schwieso == 0 & andverwa == 0 & schwager == 0) | ///
	(hhfein == 0 & vatemutt == 1 & tmp_el_unver & nichtver >= 1)

replace hhfein = 0 if ehe == 1 & partner >= 1

*********************************************************************************
* Zusammenführung der Fall-Unterteilten Haushaltstypen
* 
* Um auch die Antworten der Befragten sinnvoll zu Ketegorisieren, die betreffend
* der Zwei-Generationen-Haushalte zwar alle Verwandtschaftsbezeichungen angeben,
* aber beim jeweiligen Familienstand keine Angaben machen, werden die bisherigen
* HH-Fein-Kategorien auf hoeherem Niveau zu HH-Grob-Kategorien verdichtet.
* Bei den Befragten mit dem Wert hhfein = 0 wird dann nachgefasst.
**********************************************************************************

egen hhgrob = cut(hhfein), at(0, 10, 30, 51, 121, 132, 140, 150, 180, 190, 200) icodes

* Nachfassen
replace hhgrob = 1 if hhfein == 0 & verwand2 == -10 & hhgroesse == 1
replace hhgrob = 2 if hhfein == 0 & inlist(verwand2, 1, 2) & verwand3 == -10

replace hhgrob = 3 if hhfein == 0 & (tmp_kindgen == 1 | eigenkel >= 1) & ///
	tmp_el == 0 & tmp_groel == 0 & andverwa == 0 & nichtver == 0
replace hhgrob = 3 if hhfein == 0 & tmp_el == 1 & tmp_kindgen == 0 & tmp_groel == 0 & ///
	eigenkel == 0 & andverwa == 0 & nichtver == 0
replace hhgrob = 3 if hhfein == 0 & tmp_groel == 1 & tmp_kindgen == 0 & eigenkel == 0 & ///
	tmp_el == 0 & andverwa == 0 & nichtver == 0

*********************************************************************************
* Vergabe der Value Labels für hhfein und hhgrob
*********************************************************************************

label define hhfein ///
	10 "H1A: ALLEIN LEDIG" ///
	20 "H1B: ALLEIN GETR GESCH VERW" ///
    30 "H2A: PARTNERPAAR" ///
	40 "H2B: EHEPAAR" ///
    51 "H3A: B = LED ELTERNTEIL" ///
	52 "H3A: BERF = KIND" ///
    61 "H3B: B = ELTERNTEIL" ///
	64 "H3B: B = LEDIGES KIND" ///
    71 "H3C: B = EINER D PARTNER" ///
	72 "H3C: B = NICHTLED KIND" ///
    75 "H3C: B = LEDIGES KIND" ///
	81 "H3D: B = GROSSELTERNTEIL" ///
	83 "H3D: B = ENKEL BEIDER PARTN" ///
	91 "H3E: VOLL KERN B = ELTER" ///
	92 "H3E: VOLL KERN B = KIND" ///
	93 "H3E: UNVOLL KERN B = ELT" ///
	94 "H3E: UNVOLL KERN B = KIND" ///
   101 "H3F: VOLL 2-GEN B = ELTE" ///
   102 "H3F: UNVOLL 2-GEN B = ELTER" ///
   103 "H3F: VOLL 2-GEN B = KIND" ///
   104 "H3F: UNVOLL 2-GEN B = KIND" ///
   105 "H3F: NLED KIND + 4 ELTER" ///
   106 "H3F: NLED KIND + 3 ELTERNTE" ///
   107 "H3F: NLED KIND + 2 ELTER" ///
   108 "H3F: NLED KIND + 1 ELTERNTE" ///
   111 "H3G: GEN VOLL B = GROSSE" ///
   112 "H3G: GEN UNVOLL B = GROSSEL" ///
   113 "H3G: ENKEL + 4 GROSSELTE" ///
   114 "H3G: ENKEL + 3 GROSSELTERN" ///
   115 "H3G: ENKEL + 2 GROSSELTE" ///
   116 "H3G: ENKEL + 1 GROSSELTERNT" ///
   121 "H4: 3-GEN B = GROSSELTER" ///
   122 "H4: 3-GEN B = ELTERNTEIL" ///
   123 "H4: 3-GEN B = KIND" ///
   132 "H5: 4-GEN B = ELTERNTEIL" ///
   133 "H5: 4-GEN B = KIND" ///
   140 "H6: VERW-HH MIT FAMKERN" ///
   150 "H7A: PART + LIN + NLIN VERW" ///
   160 "H7B: NLIN + NICHTVERWAND" ///
   170 "H7C: NUR NLINEAR VERWANDT" ///
   180 "H8: WOHNGEM MIT FAMKERN" ///
   190 "H9: WOHNGEMEINSCHAFT"
label values hhfein hhfein

label define hhgrob ///
	-32 "NICHT GENERIERBAR" ///
	1 "EINPERSONEN-HAUSHALT" ///
	2 "EIN-GENERATIONEN-HH" ///
    3 "ZWEI-GENERATIONEN-HH" ///
	4 "DREI-GENERATIONEN-HH" ///
	5 "VIER-GENERATIONEN-HH" ///
	6 "VERW-HH MIT FAMKERN" ///
	7 "VERW-HH OHNE FAMKERN" ///
	8 "WOHNGEM MIT FAMKERN" ///
	9 "WOHNGEMEINSCHAFT"
label values hhgrob hhgrob

label variable hhfein "HAUSHALTS-FEINKLASSIFIKATION NACH PORST"
label variable hhgrob "HAUSHALTS-GROBKLASSIFIKATION NACH PORST"

*********************************************************************************
* Neuvergabe der Missing Value-Werte 
*********************************************************************************
egen missing = anycount(verwand*), v(-9, -7, -41)
replace hhfein = 999 if missing > 0
replace hhgrob = 999 if missing > 0

*********************************************************************************
* Hier soll versucht werden, die HH-Grob-Klassenzugehörigkeit von jenen
* Befragten zu ermitteln, die bisher "keine Angabe" (999), zugeteilt bekommen,
* die allerdings als Paare oder Alleinerziehende mit "Kindern nur im Haushalt"
* identifiziert werden können
**********************************************************************************

gen kindinhh = 0
replace kindinhh = (anzakind/missing) if hhgrob == 999


egen tmp = anycount(eigekind stiekind bruschwe stiefbru eigenkel vatemutt schwieso ///
	schwieva grovamut grovmpar andverwa nichtver schwager), v(0)
replace hhgrob = 3 if (hhgrob == 999) & ((famstan1 == 1 & verwand2 == 1 & famstan2 == 1) | ///
	(famstan1 >= 2 & famstan1 <= 5)) & tmp == 13 & kindinhh == 1
drop tmp

**********************************************************************************
* Aufbauend auf der HH-Fein-Klassifikation soll jetzt die
* F A M I L I E N T Y P O L O G I E 
* erstellt werden 
**********************************************************************************

gen kindhelp = .
forvalues i = 2/8 {
	forvalues j = 2/8 {
		replace kindhelp = 1 if (eigekind >= 1 | stiekind >= 1) & (inlist(verwand`i', 3, 4) & famstan`i' == 1) & (schwieso >= 1 & verwand`j' == 10 & famstan`j' == 1)
	}
}

gen vamuhelp = .
forvalues i = 2/8 {
	replace vamuhelp = 1 if (vatemutt == 2 & verwand`i' == 8 & famstan`i' == 1) | ///
		(schwieva == 2 & verwand`i' == 9 & famstan`i' == 1)
}

gen groshelp = .
forvalues i = 2/8 {
	replace groshelp = 1 if (grovamut == 2 & verwand`i' == 12 & famstan`i' == 1) | ///
		(grovmpar == 2 & verwand`i' == 13 & famstan`i' == 1)
}

gen famfein = 0

replace famfein = 11 if inlist(hhfein, 91, 92)
replace famfein = 12 if inlist(hhfein, 93, 94)
replace famfein = 22 if inrange(hhfein, 101, 116)
replace famfein = 21 if famfein == 22 & (ehe == 1 | kindhelp == 1 | vamuhelp == 1 | groshelp == 1)
replace famfein = 32 if inrange(hhfein , 121, 123)
replace famfein = 31 if famfein == 32 & ///
	((kindhelp == 1 & (ehe == 1 | vamuhelp == 1 | groshelp == 1)) | ///
	(ehe == 1 & (vamuhelp == 1 | groshelp == 1)) | ///
	(vamuhelp == 1 & groshelp == 1))
replace famfein = 42 if inrange(hhfein, 131, 134)
replace famfein = 41 if famfein == 42 & (kindhelp == 1 & ehe == 1 & (vamuhelp == 1 | groshelp == 1)) | ///
	(vamuhelp == 1 & groshelp == 1 & (ehe == 1 | kindhelp == 1))
replace famfein = 50 if hhfein == 140
replace famfein = 60 if hhfein == 180
replace famfein = 999 if hhfein == 999

*Haushalts-Grobklassifikation

gen famgrob = famfein
replace famgrob = round(famfein/10, 1) if inrange(famfein, 0, 60)

foreach var of varlist famfein famgrob hhfein hhgrob {
	recode `var' (0 999 = -32)
}

label variable famfein "FAMILIENTYPOLOGIE (FEIN) NACH PORST"
label variable famgrob "FAMILIENTYPOLOGIE (GROB) NACH PORST"
label define famfein	11 "VOLLST KERNFAMILIE"  12 "UNVOLL KERNFAMILIE" ///
						21 "VOLLST ZWEI-GEN-FAM" 22 "UNVOLL ZWEI-GEN-FAM" ///
						31 "VOLLST DREI-GEN-FAM" 32 "UNVOLL DREI-GEN-FAM" ///
						41 "VOLLST VIER-GEN-FAM" 42 "UNVOLL VIER-GEN-FAM" ///
						50 "ERWEITERTE FAMILIEN" 60 "HAUSHALTSFAMILIEN" ///
					   -32 "NICHT GENERIERBAR"
label define famgrob	1 "KERNFAMILIE"          2 "ZWEI-GENERAT-FAMILIE" ///
                        3 "DREI-GENERAT-FAMILIE" 4 "VIER-GENERAT-FAMILIE" ///
                        5 "ERWEITERTE FAMILIEN"  6 "HAUSHALTSFAMILIEN" ///
                      -32 "NICHT GENERIERBAR"

drop verwand* famstan* *help tmp* kindinhh missing anzakind ver*inhh hhgroesse ///
	ehe partner eigekind stiekind bruschwe stiefbru eigenkel vatemutt schwieva ///
	schwieso schwager grovamut grovmpar andverwa nichtver

save "`outfile'", replace